net-analyzer/ettercap: version bump to 0.8.3.1

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Agostino Sarubbo <ago@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/net-analyzer/ettercap/Manifest b/net-analyzer/ettercap/Manifest
index fb40201464a6..8433aab86f55 100644
--- a/net-analyzer/ettercap/Manifest
+++ b/net-analyzer/ettercap/Manifest
@@ -1 +1,2 @@
+DIST ettercap-0.8.3.1.tar.gz 6678653 BLAKE2B 2680b97454626a6f1af3b21f689ba8eed7a023c3ef5cd84d5b2b5859382f398b3a6fc622270ca41941a8a18a7bdd260af64165344a33b2e195c86ee61567f2eb SHA512 9bd71dcc1730293ee83934aca3587dfde662cb3890c12fafa557b6359f12226e5cb6f59a0db1aa11245a132b275e355e3bcc8952db921171d27b792827f148b5
 DIST ettercap-0.8.3.tar.gz 8381943 BLAKE2B f49098d61f60877d3f979d7861f36dad6ec3fbfca7ed89d8f9826867145ea36daec65a1076c893f81391218688448515ef020a9cdf9a16ffddc830bacec8eb1c SHA512 1929c986d3a17ebc693ffe8531e01c66379c0ee6ea71305ea49b6a9eece84b6da1923135311db458bdb6035feb593e525786e6cf4c465ced5a7683384d4a4ae7
diff --git a/net-analyzer/ettercap/ettercap-0.8.3.1.ebuild b/net-analyzer/ettercap/ettercap-0.8.3.1.ebuild
new file mode 100644
index 000000000000..f6f494b3507f
--- /dev/null
+++ b/net-analyzer/ettercap/ettercap-0.8.3.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A suite for man in the middle attacks"
+HOMEPAGE="https://github.com/Ettercap/ettercap"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Ettercap/${PN}.git"
+else
+	SRC_URI="https://github.com/Ettercap/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="doc geoip gtk ipv6 libressl ncurses +plugins test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/libbsd
+	dev-libs/libpcre
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	net-libs/libnet:1.1
+	>=net-libs/libpcap-0.8.1
+	sys-libs/zlib
+	geoip? ( dev-libs/geoip )
+	gtk? (
+		>=dev-libs/atk-1.2.4
+		>=dev-libs/glib-2.2.2:2
+		media-libs/freetype
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		>=x11-libs/gtk+-2.2.2:2
+		>=x11-libs/pango-1.2.3
+	)
+	ncurses? ( >=sys-libs/ncurses-5.3:= )
+	plugins? ( >=net-misc/curl-7.26.0 )"
+DEPEND="${RDEPEND}
+	doc? ( app-text/ghostscript-gpl
+		sys-apps/groff )
+	test? ( dev-libs/check )
+	sys-devel/flex
+	virtual/yacc"
+
+src_prepare() {
+	sed -i "s:Release:Release Gentoo:" CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CURSES="$(usex ncurses)"
+		-DENABLE_GTK="$(usex gtk)"
+		-DENABLE_PLUGINS="$(usex plugins)"
+		-DENABLE_IPV6="$(usex ipv6)"
+		-DENABLE_TESTS="$(usex test)"
+		-DENABLE_PDF_DOCS="$(usex doc)"
+		-DENABLE_GEOIP="$(usex geoip)"
+		-DBUNDLED_LIBS=OFF
+		-DSYSTEM_LIBS=ON
+		-DINSTALL_SYSCONFDIR="${EPREFIX}"/etc
+	)
+
+	! use gtk && mycmakeargs+=(-DINSTALL_DESKTOP=OFF)
+		#right now we only support gtk2, but ettercap also supports gtk3
+		#do we care? do we want to support both?
+	cmake_src_configure
+}