media-video/mkvtoolnix: Version bump to 75.0.0

This fixes the build with Ruby 3.2.

Also deals with unknown --with-po4a-translate configure option.

Bug: https://bugs.gentoo.org/895138
Closes: https://bugs.gentoo.org/903727
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

3 files changed, 135 insertions, 2 deletions

diff --git a/media-video/mkvtoolnix/Manifest b/media-video/mkvtoolnix/Manifest
index f07ffbf4fa32..7ad17337daf3 100644
--- a/media-video/mkvtoolnix/Manifest
+++ b/media-video/mkvtoolnix/Manifest
@@ -1 +1,2 @@
 DIST mkvtoolnix-72.0.0.tar.xz 10994204 BLAKE2B 2118837c01d8d31644e0147dfdec9fd619d18ffbab5d317e5dd84788a83cdf162ea7d72e98549bbc2ffc7953e0b80a0e23018658d8c5ad529fc719b291589a97 SHA512 dc18c6e63e724181e38753921ec3374752dbb7c4d20650cf0787e9049aaec4f6bb6c744e49b3783921804f192de742fba92826615a1edc8516d2a41621be658c
+DIST mkvtoolnix-75.0.0.tar.xz 11009552 BLAKE2B d9c32a453ac1f07e201b99fdcaaa5e553b42c1d17fafdeb1a84808ee572caf00b4b49d04c90d7801564f4856e9b3057a45ef79041e72f76bc829c3b5d9536c58 SHA512 eca45828ec3cbb540c67d12d369f3314246d08812933a018e5c4f69e8bd2fa4e17143a33a1841c5a8da3befbc22509fa508e6688ea858980d13c44aaae4ead08
diff --git a/media-video/mkvtoolnix/mkvtoolnix-75.0.0.ebuild b/media-video/mkvtoolnix/mkvtoolnix-75.0.0.ebuild
new file mode 100644
index 000000000000..628d982c71e9
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-75.0.0.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic multiprocessing qmake-utils xdg
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/mbunkus/mkvtoolnix.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://mkvtoolnix.download/sources/${P}.tar.xz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="https://mkvtoolnix.download/ https://gitlab.com/mbunkus/mkvtoolnix"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="dbus debug dvd gui nls pch test"
+RESTRICT="!test? ( test )"
+
+# check NEWS.md for build system changes entries for boost/libebml/libmatroska
+# version requirement updates and other packaging info
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/gmp:=
+	>=dev-libs/libebml-1.4.4:=
+	>=dev-libs/libfmt-8.0.1:=
+	>=dev-libs/pugixml-1.11:=
+	media-libs/flac:=
+	>=media-libs/libmatroska-1.7.1:=
+	media-libs/libogg:=
+	media-libs/libvorbis:=
+	sys-libs/zlib
+	dvd? ( media-libs/libdvdread:= )
+	dev-qt/qtcore:5
+	gui? (
+		dev-qt/qtsvg:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtmultimedia:5
+	)
+	app-text/cmark:0=
+	dbus? ( dev-qt/qtdbus:5 )
+"
+DEPEND="${RDEPEND}
+	>=dev-cpp/nlohmann_json-3.9.1
+	>=dev-libs/utfcpp-3.1.2
+	test? ( dev-cpp/gtest )
+"
+BDEPEND="
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-ruby/rake
+	virtual/pkgconfig
+	nls? (
+		sys-devel/gettext
+		app-text/po4a
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/mkvtoolnix-58.0.0-qt5dbus.patch
+	"${FILESDIR}"/mkvtoolnix-67.0.0-no-uic-qtwidgets.patch
+)
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == *9999 ]]; then
+		./autogen.sh || die
+	fi
+
+	# bug #692018
+	sed -i -e 's/pandoc/diSaBlEd/' ac/pandoc.m4 || die
+
+	eautoreconf
+
+	# remove bundled libs
+	rm -r lib/{fmt,libebml,libmatroska,nlohmann-json,pugixml,utf8-cpp} || die
+}
+
+src_configure() {
+	# bug #692322, use system dev-libs/utfcpp
+	append-cppflags -I"${ESYSROOT}"/usr/include/utf8cpp
+
+	local myeconfargs=(
+		$(use_enable debug)
+		$(usex pch "" --disable-precompiled-headers)
+		$(use_enable dbus)
+
+		# Qt (of some version) is always needed, even for non-GUI builds,
+		# to do e.g. MIME detection. See e.g. bug #844097.
+		# But most of the Qt deps are conditional on a GUI build.
+		--disable-qt6
+		--enable-qt5
+		$(use_enable gui)
+		--with-qmake="$(qt5_get_bindir)"/qmake
+
+		$(use_with dvd dvdread)
+		$(use_with nls gettext)
+		$(usex nls "" --with-po4a=false)
+		--disable-update-check
+		--disable-optimization
+		--with-boost="${ESYSROOT}"/usr
+		--with-boost-libdir="${ESYSROOT}"/usr/$(get_libdir)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	rake V=1 -j$(makeopts_jobs) || die
+}
+
+src_test() {
+	rake V=1 -j$(makeopts_jobs) tests:unit || die
+	rake V=1 -j$(makeopts_jobs) tests:run_unit || die
+}
+
+src_install() {
+	DESTDIR="${D}" rake -j$(makeopts_jobs) install || die
+
+	einstalldocs
+	dodoc NEWS.md
+	doman doc/man/*.1
+}
diff --git a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
index 23a2e80da85d..628d982c71e9 100644
--- a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
+++ b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -104,7 +104,7 @@ src_configure() {
 
 		$(use_with dvd dvdread)
 		$(use_with nls gettext)
-		$(usex nls "" --with-po4a-translate=false)
+		$(usex nls "" --with-po4a=false)
 		--disable-update-check
 		--disable-optimization
 		--with-boost="${ESYSROOT}"/usr