media-video/noad: fixed compile for ffmpeg-3, wrt bug 614220

Package-Manager: Portage-2.3.41, Repoman-2.3.9

6 files changed, 90 insertions, 9 deletions

diff --git a/media-video/noad/Manifest b/media-video/noad/Manifest
index 93ef3d0545d5..947101c403af 100644
--- a/media-video/noad/Manifest
+++ b/media-video/noad/Manifest
@@ -1,2 +1,3 @@
 DIST noad-0.7.3.tar.bz2 174036 BLAKE2B 11fbe9e794981b1666b04ff9d8909972a00db2daff90819d651324704836949af85278e807e7e6902b0198fd4dcd167c8722adcf816d95e15fe808efb93420a1 SHA512 0edc81c9b689c49b99cd68b80bf7acbb0af9757b4d5439edd0610ca96bf0ee4783844aa0dfe52e3303b21f5794af3ad9a216371d4e698bbf26f24bc31be43c66
+DIST noad-0.8.6-ffmpeg3.4.diff.bz2 6261 BLAKE2B 4c1de8b72c9b25a056cabb5a74b4d9bbc42f6586b4e2166bf2cf5ac76d7617df3318a4a4b21fa5dbfb601e2f9bacc7bd2d8b54705750a2d761c5a73c5c745578 SHA512 f7b4879902e2344099ef337094fc8be1c4322d2fa1ed5d7c275adfed9dfcc1644cc18743191ffd4daaa44a83cf3936a8dd8a978c66aaeae18a38c6164a608b02
 DIST noad-0.8.6.tar.bz2 188085 BLAKE2B fa9ae43984509f6da17028cda11f69dae0a74afcabe8daaaf2661d9791229bf1d5374b26abbcc9cd8f887b42c188a0d4871ae059dabac3b9bb9175533f096100 SHA512 ffca9e8bc78719350ffdfe59a4f258033f843ddf761ca5d8893cde5a4968a644c0318fd86b60e7b9e78b0650f8f02c68e6f7a95f4dfb702ab30d84ad3750c9e9
diff --git a/media-video/noad/metadata.xml b/media-video/noad/metadata.xml
index b76754b18b74..8251361a1e12 100644
--- a/media-video/noad/metadata.xml
+++ b/media-video/noad/metadata.xml
@@ -10,7 +10,7 @@
 		<name>Gentoo Video project</name>
 	</maintainer>
 	<use>
-		<flag name="libmpeg2">Support for libmpeg2 library</flag>
+		<flag name="libmpeg2">Build support for mpeg2 over media-libs/libmpeg2 rather than using ffmpeg</flag>
 	</use>
 	<longdescription lang="en">
 		Mark commercial Breaks in VDR records. 
diff --git a/media-video/noad/noad-0.7.3-r1.ebuild b/media-video/noad/noad-0.7.3-r1.ebuild
index 2a433cde6db5..3835c9d4b831 100644
--- a/media-video/noad/noad-0.7.3-r1.ebuild
+++ b/media-video/noad/noad-0.7.3-r1.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 inherit autotools eutils toolchain-funcs
 
 DESCRIPTION="Mark commercial Breaks in VDR records"
diff --git a/media-video/noad/noad-0.8.6-r1.ebuild b/media-video/noad/noad-0.8.6-r1.ebuild
index ae96bfd4fd50..60d75aed517f 100644
--- a/media-video/noad/noad-0.8.6-r1.ebuild
+++ b/media-video/noad/noad-0.8.6-r1.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 inherit autotools eutils toolchain-funcs
 
 DESCRIPTION="Mark commercial breaks in VDR recordings"
@@ -27,7 +27,7 @@ src_prepare() {
 	sed -i -e 's:2001:6419:' svdrpc.cpp main.cpp
 
 	# tested libav-9, ffmepg-2.2.9
-	epatch "${FILESDIR}/patches-0.8.x/${P}-libav9.diff" \
+	eapply "${FILESDIR}/patches-0.8.x/${P}-libav9.diff" \
 		"${FILESDIR}/patches-0.8.x/${P}-ffmpeg25.patch"
 
 	eautoreconf
diff --git a/media-video/noad/noad-0.8.6-r2.ebuild b/media-video/noad/noad-0.8.6-r2.ebuild
index cd819660440a..d9c62f84e4be 100644
--- a/media-video/noad/noad-0.8.6-r2.ebuild
+++ b/media-video/noad/noad-0.8.6-r2.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 inherit autotools eutils toolchain-funcs
 
 DESCRIPTION="Mark commercial breaks in VDR recordings"
@@ -31,7 +31,7 @@ src_prepare() {
 	sed -e "sCODEC_ID_PROBE:AV_CODEC_ID_PROBE:" -i ffmpeg_decoder.cpp
 
 	# tested libav-9, ffmepg-2.2.9
-	epatch "${FILESDIR}/patches-0.8.x/${P}-libav9.diff" \
+	eapply "${FILESDIR}/patches-0.8.x/${P}-libav9.diff" \
 		"${FILESDIR}/patches-0.8.x/${P}-ffmpeg25.patch"
 
 	eautoreconf
diff --git a/media-video/noad/noad-0.8.6-r3.ebuild b/media-video/noad/noad-0.8.6-r3.ebuild
new file mode 100644
index 000000000000..ab6a5dbf53c8
--- /dev/null
+++ b/media-video/noad/noad-0.8.6-r3.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools eutils toolchain-funcs
+
+DESCRIPTION="Mark commercial breaks in VDR recordings"
+HOMEPAGE="http://noad.net23.net/"
+SRC_URI="http://noad.net23.net/${P}.tar.bz2
+		http://vdr.websitec.de/download/${PN}/${P}-ffmpeg3.4.diff.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ffmpeg imagemagick libmpeg2"
+
+RDEPEND="
+	libmpeg2? ( media-libs/libmpeg2:= )
+	ffmpeg? ( virtual/ffmpeg )
+	imagemagick? ( media-gfx/imagemagick )
+	!media-plugins/vdr-markad"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="|| ( ffmpeg libmpeg2 )"
+
+src_prepare() {
+	default
+
+	#compile tested libav-13, ffmepg-3.4
+	eapply "${WORKDIR}/${P}-ffmpeg3.4.diff"
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(usex imagemagick '--with-magick') \
+		$(usex ffmpeg '' '--without-ffmpeg') \
+		$(usex libmpeg2 '' '--without-libmpeg2') \
+		--with-tools
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"		# see bug #469810
+}
+
+src_install() {
+	dobin noad showindex checkMarks
+	use imagemagick && dobin markpics
+
+	dodoc README INSTALL
+	# example scripts are installed as dokumentation
+	dodoc allnewnoad allnoad allnoadnice clearlogos noadcall.sh noadifnew stat2html statupd
+
+	newconfd "${FILESDIR}"/confd_vdraddon.noad vdraddon.noad
+
+	insinto /usr/share/vdr/record
+	doins "${FILESDIR}"/record-50-noad.sh
+
+	insinto /usr/share/vdr/shutdown
+	doins "${FILESDIR}"/pre-shutdown-15-noad.sh
+
+	insinto /etc/vdr/reccmds
+	doins "${FILESDIR}"/reccmds.noad.conf
+
+	exeinto /usr/share/vdr/bin
+	doexe "${FILESDIR}"/noad-reccmd
+}
+
+pkg_postinst() {
+	elog
+	elog "To integrate noad in VDR you should do this:"
+	elog
+	elog "start and set Parameter in /etc/conf.d/vdraddon.noad"
+	elog
+	elog "Note: You can use here all parameters for noad,"
+	elog "please look in the documentation of noad."
+}