media-sound/strawberry: dropped obsolete 1.0.17

Bug: https://bugs.gentoo.org/905360
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 0 insertions, 123 deletions

diff --git a/media-sound/strawberry/Manifest b/media-sound/strawberry/Manifest
index dc334249d141..deec8da7dc22 100644
--- a/media-sound/strawberry/Manifest
+++ b/media-sound/strawberry/Manifest
@@ -1,2 +1 @@
-DIST strawberry-1.0.15.tar.xz 11230148 BLAKE2B a6ee4dac23dc3c4707a6b31f39bd794975e2c8aeab438419cf2972a1a7f3b9bf54837550db542e2c19bcf08346b04ec9d952e84529865e067c5e7df0a9e0189d SHA512 074b3da1dea22e1e21fcb1039d77e9edf898953ff0a16b28d4ad36052b454e669a4a92e988f1091e7987104149764e411ca68bd95b5f1e18f3e744d2c7dd3625
 DIST strawberry-1.0.17.tar.xz 11244908 BLAKE2B ad838be23bbf441e1617ccc45e48e54baa829f327fccfc8f3070fd211eaaaa00d690cecef36858f91b59a1114c4df84c9b72b98ec3affb56f9516167d6fb8484 SHA512 7629997f1734b537057b8e49ed443c48733ce5787ebf79939c77aa07f193d36e5ced15df62c03b784644fc058b3067d46e192a0de0cc9fb0a2338dc76d738973
diff --git a/media-sound/strawberry/strawberry-1.0.15.ebuild b/media-sound/strawberry/strawberry-1.0.15.ebuild
deleted file mode 100644
index 52c17b9c7573..000000000000
--- a/media-sound/strawberry/strawberry-1.0.15.ebuild
+++ /dev/null
@@ -1,122 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic plocale xdg
-
-PLOCALES="ca cs de es es_AR es_ES es_MX fi fr hu id it ja ko nb nl pl pt_BR ru sv uk zh_CN"
-
-DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
-HOMEPAGE="https://www.strawberrymusicplayer.org/"
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/strawberrymusicplayer/strawberry"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/strawberrymusicplayer/strawberry/releases/download/${PV}/${P}.tar.xz"
-	KEYWORDS="amd64 ~ppc64 x86"
-fi
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="cdda debug +gstreamer icu ipod moodbar mtp pulseaudio +udisks vlc"
-
-BDEPEND="
-	dev-qt/linguist-tools:5
-	sys-devel/gettext
-	virtual/pkgconfig
-"
-COMMON_DEPEND="
-	dev-db/sqlite:=
-	dev-libs/glib:2
-	dev-libs/protobuf:=
-	dev-qt/qtconcurrent:5
-	dev-qt/qtcore:5
-	dev-qt/qtdbus:5
-	dev-qt/qtgui:5
-	dev-qt/qtnetwork:5[ssl]
-	dev-qt/qtsql:5[sqlite]
-	dev-qt/qtwidgets:5
-	dev-qt/qtx11extras:5
-	media-libs/alsa-lib
-	media-libs/taglib
-	x11-libs/libX11
-	cdda? ( dev-libs/libcdio:= )
-	gstreamer? (
-		media-libs/chromaprint:=
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-	)
-	icu? ( dev-libs/icu:= )
-	ipod? ( media-libs/libgpod )
-	moodbar? ( sci-libs/fftw:3.0 )
-	mtp? ( media-libs/libmtp )
-	pulseaudio? ( media-sound/pulseaudio )
-	vlc? ( media-video/vlc )
-"
-# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
-RDEPEND="${COMMON_DEPEND}
-	gstreamer? (
-		media-plugins/gst-plugins-meta:1.0
-		media-plugins/gst-plugins-soup:1.0
-		media-plugins/gst-plugins-taglib:1.0
-	)
-	mtp? ( gnome-base/gvfs[mtp] )
-	udisks? ( sys-fs/udisks:2 )
-"
-DEPEND="${COMMON_DEPEND}
-	dev-cpp/gtest
-	dev-libs/boost
-	dev-qt/qttest:5
-"
-
-DOCS=( Changelog README.md )
-
-REQUIRED_USE="
-	cdda? ( gstreamer )
-	|| ( gstreamer vlc )
-"
-
-src_prepare() {
-	plocale_find_changes "src/translations" "" ".po"
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	# spotify is not in portage
-	local mycmakeargs=(
-		-DBUILD_WERROR=OFF
-		# avoid automagically enabling of ccache (bug #611010)
-		-DCCACHE_EXECUTABLE=OFF
-		-DENABLE_GIO=ON
-		-DLINGUAS="$(plocale_get_locales)"
-		-DENABLE_AUDIOCD="$(usex cdda)"
-		-DENABLE_GSTREAMER="$(usex gstreamer)"
-		-DUSE_ICU="$(usex icu)"
-		-DENABLE_LIBGPOD="$(usex ipod)"
-		-DENABLE_LIBMTP="$(usex mtp)"
-		-DENABLE_LIBPULSE="$(usex pulseaudio)"
-		-DENABLE_MOODBAR="$(usex moodbar)"
-		-DENABLE_MUSICBRAINZ="$(usex gstreamer)"
-		-DENABLE_SONGFINGERPRINTING="$(usex gstreamer)"
-		-DENABLE_UDISKS2="$(usex udisks)"
-		-DENABLE_VLC="$(usex vlc)"
-		# Disable until we have qt6 in the tree
-		-DWITH_QT6=OFF
-	)
-
-	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
-
-	cmake_src_configure
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if use gstreamer ; then
-		elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
-		elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
-		elog "depending on your preferences"
-	fi
-}