media-sound/qmmp: bump to 1.4.2

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 157 insertions, 0 deletions

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index 0ee6babb1982..99e2e15326ec 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1 +1,2 @@
 DIST qmmp-1.4.1.tar.bz2 1296224 BLAKE2B 4a4b72f30bbfb06d312d69c9c0d48fcaaed2d936453ab29c0bd5223819358d2894f4f016a8203c2ea15b7a193b811ae2892e700dec98e580393a9fbf5e0f767c SHA512 af971447383730328e33dc724b9d598a26404517d5aa6e8bb5a2d84bbeb1f628d363383bb5ddc571855d8416b084edd09f64174de7985788671e47317ec9f1bf
+DIST qmmp-1.4.2.tar.bz2 1295867 BLAKE2B ce282f543dc6b14ccd027aa9a4ad85f190a8aee149049798ad5e51bf944cd34ce7773dcfb7b6ea4bdf0a8a69baea430802f04de631e9b12b68d2d23a8c599461 SHA512 00ed0c4bd74dc50294c9d8e717f249a577fb26f5d4eb93dbc42c6c79964188fd885ab577904dea5aec31db0d2b828d7038febca1ffdfd2f4bfe81f931bbed7ff
diff --git a/media-sound/qmmp/qmmp-1.4.2.ebuild b/media-sound/qmmp/qmmp-1.4.2.ebuild
new file mode 100644
index 000000000000..45e48d80e0dc
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.4.2.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
+		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.3"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
+gnome jack ladspa lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? ( media-video/ffmpeg:= )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		virtual/jack
+	)
+	ladspa? ( media-plugins/cmt-plugins )
+	mad? ( || (
+		media-libs/libmad
+		media-sound/mpg123
+	) )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2-only]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm:=
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake_src_configure
+}