media-sound/exaile: eapi8, added python 3.10, deps versions cleanup

Bug: https://bugs.gentoo.org/846062
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 81 insertions, 9 deletions

diff --git a/media-sound/exaile/exaile-4.1.1-r1.ebuild b/media-sound/exaile/exaile-4.1.1-r1.ebuild
new file mode 100644
index 000000000000..a8ee142fac0e
--- /dev/null
+++ b/media-sound/exaile/exaile-4.1.1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit python-single-r1 xdg
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/exaile/exaile.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV/_/-}/${PN}-${PV/_/}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+DESCRIPTION="GTK+ based media player aiming to be similar to Amarok"
+HOMEPAGE="https://www.exaile.org/"
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+# IUSE+=cddb if have dev-python/cddb-py
+IUSE="libnotify nls scrobbler"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
+RDEPEND="${PYTHON_DEPS}
+	media-libs/gst-plugins-base:1.0
+	media-libs/gst-plugins-good:1.0
+	media-plugins/gst-plugins-meta:1.0
+	x11-libs/gtk+:3[introspection]
+	libnotify? ( x11-libs/libnotify[introspection] )
+	$(python_gen_cond_dep '
+		dev-python/bsddb3[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		media-libs/mutagen[${PYTHON_USEDEP}]
+		scrobbler? ( dev-python/pylast[${PYTHON_USEDEP}] )
+	')
+"
+
+RESTRICT="test" #315589
+
+PATCHES=(
+	"${FILESDIR}/${P}-metainfo.patch"
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_compile() {
+	use nls && emake locale
+}
+
+src_install() {
+	emake \
+		PREFIX=/usr \
+		LIBINSTALLDIR=/usr/$(get_libdir) \
+		DESTDIR="${D}" \
+		install$(use nls || echo _no_locale)
+
+	python_optimize "${D}/usr/$(get_libdir)/${PN}"
+	python_optimize "${D}/usr/share/${PN}"
+}
diff --git a/media-sound/exaile/exaile-9999.ebuild b/media-sound/exaile/exaile-9999.ebuild
index 93bda21f7a3e..36c7f3272d08 100644
--- a/media-sound/exaile/exaile-9999.ebuild
+++ b/media-sound/exaile/exaile-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_COMPAT=( python3_{8..10} )
 inherit python-single-r1 xdg
 
 if [[ ${PV} == "9999" ]]; then
@@ -30,18 +30,18 @@ BDEPEND="
 	)
 "
 RDEPEND="${PYTHON_DEPS}
-	>=media-libs/gst-plugins-base-1.6:1.0
-	>=media-libs/gst-plugins-good-1.4:1.0
+	media-libs/gst-plugins-base:1.0
+	media-libs/gst-plugins-good:1.0
 	media-plugins/gst-plugins-meta:1.0
-	>=x11-libs/gtk+-3.10:3[introspection]
-	libnotify? ( >=x11-libs/libnotify-0.7[introspection] )
+	x11-libs/gtk+:3[introspection]
+	libnotify? ( x11-libs/libnotify[introspection] )
 	$(python_gen_cond_dep '
 		dev-python/bsddb3[${PYTHON_USEDEP}]
 		dev-python/dbus-python[${PYTHON_USEDEP}]
 		dev-python/gst-python:1.0[${PYTHON_USEDEP}]
 		dev-python/pycairo[${PYTHON_USEDEP}]
-		>=dev-python/pygobject-3.13.2:3[${PYTHON_USEDEP}]
-		>=media-libs/mutagen-1.10[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		media-libs/mutagen[${PYTHON_USEDEP}]
 		scrobbler? ( dev-python/pylast[${PYTHON_USEDEP}] )
 	')
 "