media-radio/tucnak: add 4.64

Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index 0fb5b9faae42..612bf274c469 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.61.tar.gz 6824381 BLAKE2B f995271f309d24725993bd243ade28744a81d5ab80f994dd3425336930bcd8212433f17d682575d3725243c0e1fc84510e9bd063a6b5372158d3a88558898e34 SHA512 67d17da2a321492c8c38f2207570631851122fe2615f7cc20716ad0906b0fc2422e414e0be91fdfad2474b08d20c4c05c0d2aec9ad2d1d6afc3450af0d9eeb62
+DIST tucnak-4.64.tar.gz 6765553 BLAKE2B e093080db4e019a91cc8e95c4262bad039a2a158c9823337cb9e12691de18c6d0ec54aeb1d21ff7bb8c8d6b7b63e8761bb9a3078d76a4f9a98093b6d92d43d22 SHA512 9aa85fc7669083aadc2caec2577f0d65cc342e041c34bc4f9e8f3315d867eb99cf4296e25d83169d2b5b5d3f33c230922882312ea416eb3dce4f4fc1f47ffed0
diff --git a/media-radio/tucnak/tucnak-4.64.ebuild b/media-radio/tucnak/tucnak-4.64.ebuild
new file mode 100644
index 000000000000..44d4452c95e0
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.64.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib portaudio rtlsdr suid"
+
+RDEPEND="dev-libs/glib:2
+	~dev-libs/libzia-4.64
+	media-libs/libsndfile
+	media-libs/libsdl2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0= )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )
+	portaudio? ( media-libs/portaudio )
+	rtlsdr? ( net-wireless/rtl-sdr )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) \
+		$(use_with hamlib) \
+		$(use_with fftw fftw3) \
+		$(use_with portaudio) \
+		$(use_with rtlsdr) \
+		--without-hidapi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}