media-libs/gst-plugins-bad: add 1.20.3

Signed-off-by: Sam James <sam@gentoo.org>
Signed-off-by: Igor V. Kovalenko <igor.v.kovalenko@gmail.com>

2 files changed, 89 insertions, 0 deletions

diff --git a/media-libs/gst-plugins-bad/Manifest b/media-libs/gst-plugins-bad/Manifest
index 8afe0c32cc8d..fdff776ab51a 100644
--- a/media-libs/gst-plugins-bad/Manifest
+++ b/media-libs/gst-plugins-bad/Manifest
@@ -1 +1,2 @@
 DIST gst-plugins-bad-1.20.2.tar.xz 6216208 BLAKE2B bbbe77a1255991a2f96696996fb0c99f14f6d63fef455feb1ce90ae518bb9f80fd61bcfb223c20407b8d6240faaa93478495f8e9fda16fab36a311d167e88e25 SHA512 3f98973dc07ead745418e0a30f9f6b5c8d328e3d126f54d92c10ab5da04271768a5c5dffc36ea24ccf8fb516b1e3733be9fb18dc0db419dea4d37d17018f8a70
+DIST gst-plugins-bad-1.20.3.tar.xz 6222824 BLAKE2B 01aae59adbe76b8e50a49fb8bb8037e6f3aa93cbc2b658aab05ebbf30f8d1aef98c1981712caa39e3c9d08f1e0c9d76f2f874f7d2fdd994b3a0735b2809eafdf SHA512 cfcf126eabff550455decd7054a269b73489708c10a6b6090dddb5fde29bfba07ed330c339927ff170e025fa3a08d2ffb822322dc3798679366207a54132c71b
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-1.20.3.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-1.20.3.ebuild
new file mode 100644
index 000000000000..276f18d39a2f
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-1.20.3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GST_ORG_MODULE="gst-plugins-bad"
+PYTHON_COMPAT=( python3_{8,9,10} )
+inherit gstreamer-meson python-any-r1
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# TODO: egl and gtk IUSE only for transition
+IUSE="X bzip2 +egl gles2 gtk +introspection +opengl +orc vnc wayland" # Keep default IUSE mirrored with gst-plugins-base where relevant
+
+# X11 is automagic for now, upstream #709530 - only used by librfb USE=vnc plugin
+# We mirror opengl/gles2 from -base to ensure no automagic openglmixers plugin (with "opengl?" it'd still get built with USE=-opengl here)
+# FIXME	gtk? ( >=media-plugins/gst-plugins-gtk-${PV}:${SLOT}[${MULTILIB_USEDEP}] )
+RDEPEND="
+	!media-plugins/gst-transcoder
+	>=media-libs/gstreamer-${PV}:${SLOT}[${MULTILIB_USEDEP},introspection?]
+	>=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP},egl?,introspection?,gles2=,opengl=]
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
+	vnc? ( X? ( x11-libs/libX11[${MULTILIB_USEDEP}] ) )
+	wayland? (
+		>=dev-libs/wayland-1.4.0[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+		>=dev-libs/wayland-protocols-1.15
+	)
+
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README.md RELEASE )
+
+# FIXME: gstharness.c:889:gst_harness_new_with_padnames: assertion failed: (element != NULL)
+RESTRICT="test"
+
+# Fixes backported to 1.20.1, to be removed in 1.20.2+
+PATCHES=(
+)
+
+src_prepare() {
+	default
+	addpredict /dev # Prevent sandbox violations bug #570624
+}
+
+multilib_src_configure() {
+	GST_PLUGINS_NOAUTO="shm ipcpipeline librfb hls"
+
+	local emesonargs=(
+		-Dshm=enabled
+		-Dipcpipeline=enabled
+		-Dhls=disabled
+		$(meson_feature vnc librfb)
+
+		$(meson_feature wayland)
+	)
+
+	if use opengl || use gles2; then
+		myconf+=( -Dgl=enabled )
+	else
+		myconf+=( -Dgl=disabled )
+	fi
+
+	gstreamer_multilib_src_configure
+}
+
+multilib_src_test() {
+	# Tests are slower than upstream expects
+	CK_DEFAULT_TIMEOUT=300 gstreamer_multilib_src_test
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}