media-gfx/darktable: add 4.0.0

Closes: https://bugs.gentoo.org/857030
Signed-off-by: Marek Szuba <marecki@gentoo.org>

3 files changed, 181 insertions, 0 deletions

diff --git a/media-gfx/darktable/Manifest b/media-gfx/darktable/Manifest
index b6fabb228637..8921b8aec839 100644
--- a/media-gfx/darktable/Manifest
+++ b/media-gfx/darktable/Manifest
@@ -1,7 +1,10 @@
 DIST darktable-3.8.0.tar.xz 5415532 BLAKE2B a2295d9145806720c702d30a334f4d1c483fc651dfda8a39617daed4a71a436bfaa5b6b379f5ec0ee4bbec5f6f5eabbcb589b63644b5698100dd1672710d1531 SHA512 ce95983cbe3ca899103b4f5ee560fdbeeb441dccd453ac4d858b14a25050229e1e780595c66bfb491c88db35c128054f649b365d701ef4b19cf252bd847ffa59
 DIST darktable-3.8.1.tar.xz 5514756 BLAKE2B e17bf4cc8f8d3f3fd6649c66c56777aa1e946a91cec1bc3b4c59ba1285aa16c608f725f549622b740417a8040a7bb5d63b2378997a05c2095f1b6814c05815de SHA512 8b1b0c9e1a0bd9b327d34d28fe33dd1a2c7255864f6fa0c15af364a029aaa3cff5e039ff6461e48d3b4327b7656efe70ad9da12245d3a01d7566545d191448ba
+DIST darktable-4.0.0.tar.xz 5829684 BLAKE2B 91198a47c4dab3368c934815425f430ae5b23e35f585a6c2b70322932cfd7fff19db76bd5f1dd50da81be1b8c9b82b12cb2c6c349e4808432f2ed195a015ecc2 SHA512 16b1cce589bdcd9c47685c9bd4705d35a739cfbad35ec7f414ce38848decc2e156bcbc7fe40f15026851927171072219ee0435e7cc64ca6fd763e479be5b5156
 DIST darktable-usermanual-3.8.de.pdf 32795040 BLAKE2B f8669e1982be19bc739add60d125a5818894a7a4a6414ba15aae5e5df41ec6729c99f907e3008c42acbd6f60bc4a5d33e20d7180621d135f9fd342e6190ae6a5 SHA512 ff77afcc9a20fec36891d4487d167e40d30a1deef6418dc6bb73c94d8171b42e5edc5420457c96e08ab8581175e691f8adf91ef5259367edba55f1441d4a86d3
 DIST darktable-usermanual-3.8.en.pdf 33484632 BLAKE2B 90a4e1021917f5fad7a5a9a58e2fec95af14119ca4b48325f3e5b55e96b89f9d82b8aaa676268a255fa97cf834a109b410004a549d16742a1b33db880c46fb67 SHA512 b21683f200daca3d0ed7c3364d0c6703d976fd800d1d2ffe51df1c6cfcf2188de681cdddbf92962629a3866e18014377a58ea0e54a9fa727b663972b7f1de79a
 DIST darktable-usermanual-3.8.fr.pdf 33479509 BLAKE2B 988824b60277ea0264fec61a1157a1de048cd512a172bc86276a043c06da3a684e971cef04c31122a78b3e7305157331e6cb86cfce7a4dc4dd9dc8697eddf743 SHA512 1383bb54face948bbbad895be2470c1b13ece71c325edf40402b3416a5d9653d2e1f8c4dbfa30edd10f02c1df8b8243c9e86948c5da8d2033e28ee3c6e04bbcc
 DIST darktable-usermanual-3.8.pt_br.pdf 33648057 BLAKE2B afb6d3c1ea6b709e535e10ae2a491fb6a87c84dcfe17823a518931bda0cd8595cda72905cffc01698e60c3df991451a5cccbfcdea82966a506b2d29d61298f09 SHA512 8734a9e6c57ba37f32966873b85584c50968c1c895fa4e9d953e129bb5834f254ca46e20741d5664429ef7d6379e5a35e59f8ecb517ca88ff536b49a8216b603
 DIST darktable-usermanual-3.8.uk.pdf 33663424 BLAKE2B abeb7a04b58e7ef508b415fe11073396c78964e91fbd3face8481cd6b09cf88525b1b6bdd2988bd57d25112cd59c8c05e209931f94004349cf5b8a7a3ca59e39 SHA512 e1a81771006f5d6b7e4088455b6b444ea87b27a788cc196c2bc0b0b5d0afde241ea9e2bdbd3ffe79871f39d756d710d8e16c082a21b1194efb71f78e8724af9a
+DIST darktable-usermanual-4.0.en.pdf 26585692 BLAKE2B 85083af2227e4e16a658cfce435339410e2cf4f03df1a62cf2a54b743232b82093d8012c1212978f08c021585d5cb4ee4b47d4cbfd399a8a9505d0cb32932618 SHA512 789fb6a309608ad10fccfd61eca24b6176fe9ce8ad53dd9840a7e3175598d9d6b7c8357d4852fc787dbfe80e32e696d680e3a7b9a2663ef4d00ef424d3341fc6
+DIST darktable-usermanual-4.0.uk.pdf 26781033 BLAKE2B 6d73b690dfebc590971325242fdb6d6de5577219eff6b20dec08a3a53a9529cb53031a36fd0ac45b509f4cb885bafdce38ce1f8bd1c4a255aa2a137bc367d87c SHA512 e897bca98470d9d51bdfa807850af5222cbba527ba46df9b713776ebdc5dc8b946758e4c25f1df478c2c01408d08a91467cc75b5a199042b42c93627dc6d9846
diff --git a/media-gfx/darktable/darktable-4.0.0.ebuild b/media-gfx/darktable/darktable-4.0.0.ebuild
new file mode 100644
index 000000000000..53e08e8e3c52
--- /dev/null
+++ b/media-gfx/darktable/darktable-4.0.0.ebuild
@@ -0,0 +1,177 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-4 )
+
+inherit cmake flag-o-matic lua-single toolchain-funcs xdg
+
+DESCRIPTION="A virtual lighttable and darkroom for photographers"
+HOMEPAGE="https://www.darktable.org/"
+LICENSE="GPL-3 CC-BY-3.0"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/darktable-org/${PN}.git"
+
+	LANGS=" af ca cs da de el es fi fr gl he hu it ja nb nl pl pt-BR pt-PT ro ru sk sl sq sv th uk zh-CN zh-TW"
+else
+	DOC_PV=$(ver_cut 1-2)
+	MY_PV="${PV/_/}"
+	MY_P="${P/_/.}"
+
+	SRC_URI="https://github.com/darktable-org/${PN}/releases/download/release-${MY_PV}/${MY_P}.tar.xz
+		doc? (
+			https://docs.darktable.org/usermanual/${DOC_PV}/en/${PN}_user_manual.pdf -> ${PN}-usermanual-${DOC_PV}.en.pdf
+			l10n_uk? ( https://docs.darktable.org/usermanual/${DOC_PV}/uk/${PN}_user_manual.pdf -> ${PN}-usermanual-${DOC_PV}.uk.pdf )
+		)"
+
+	KEYWORDS="~amd64 ~arm64 -x86"
+	LANGS=" cs de eo es fi fr he hu it ja nl pt-BR ru sl tr uk zh-CN"
+fi
+
+IUSE="avif colord cpu_flags_x86_avx cpu_flags_x86_sse3 cups doc flickr gamepad geolocation gmic gnome-keyring gphoto2 graphicsmagick heif jpeg2k kwallet lto lua midi nls opencl openmp openexr test tools webp
+	${LANGS// / l10n_}"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-python/jsonschema-3.2.0 )"
+DEPEND="dev-db/sqlite:3
+	dev-libs/icu:=
+	dev-libs/json-glib
+	dev-libs/libxml2:2
+	>=dev-libs/pugixml-1.8:0=
+	gnome-base/librsvg:2
+	>=media-gfx/exiv2-0.25-r2:0=[xmp]
+	media-libs/lcms:2
+	>=media-libs/lensfun-0.2.3:0=
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:0=
+	media-libs/tiff:0
+	net-libs/libsoup:2.4
+	net-misc/curl
+	sys-libs/zlib:=
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/pango
+	avif? ( >=media-libs/libavif-0.8.2:= )
+	colord? ( x11-libs/colord-gtk:0= )
+	cups? ( net-print/cups )
+	flickr? ( media-libs/flickcurl )
+	gamepad? ( media-libs/libsdl2 )
+	geolocation? ( >=sci-geosciences/osm-gps-map-1.1.0 )
+	gmic? ( media-gfx/gmic )
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	gphoto2? ( media-libs/libgphoto2:= )
+	graphicsmagick? ( media-gfx/graphicsmagick )
+	heif? ( media-libs/libheif:= )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lua? ( ${LUA_DEPS} )
+	midi? ( media-libs/portmidi )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:= )
+	webp? ( media-libs/libwebp:0= )"
+RDEPEND="${DEPEND}
+	kwallet? ( >=kde-frameworks/kwallet-5.34.0-r1 )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.0_find-opencl-header.patch
+	"${FILESDIR}"/${PN}-3.0.2_cmake-march-autodetection.patch
+	"${FILESDIR}"/${PN}-3.4.0_jsonschema-automagic.patch
+	"${FILESDIR}"/${PN}-3.4.1_libxcf-cmake.patch
+	"${FILESDIR}"/${PN}-3.8.0_libs-deps-automagic.patch
+)
+#	"${FILESDIR}"/${PN}-3.6.1_openexr.patch
+
+S="${WORKDIR}/${P/_/~}"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		# Bug #695658
+		if tc-is-gcc; then
+			test-flags-CC -floop-block &> /dev/null || \
+				die "Please switch to a gcc version built with USE=graphite"
+		fi
+
+		use openmp && tc-check-openmp
+	fi
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	use cpu_flags_x86_avx && append-flags -mavx
+	use cpu_flags_x86_sse3 && append-flags -msse3
+
+	sed -i -e 's:/appdata:/metainfo:g' data/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CURVE_TOOLS=$(usex tools)
+		-DBUILD_NOISE_TOOLS=$(usex tools)
+		-DBUILD_PRINT=$(usex cups)
+		-DCUSTOM_CFLAGS=ON
+		-DDONT_USE_INTERNAL_LUA=ON
+		-DRAWSPEED_ENABLE_LTO=$(usex lto)
+		-DTESTBUILD_OPENCL_PROGRAMS=OFF
+		-DUSE_AVIF=$(usex avif)
+		-DUSE_CAMERA_SUPPORT=$(usex gphoto2)
+		-DUSE_COLORD=$(usex colord)
+		-DUSE_FLICKR=$(usex flickr)
+		-DUSE_GMIC=$(usex gmic)
+		-DUSE_GRAPHICSMAGICK=$(usex graphicsmagick)
+		-DUSE_KWALLET=$(usex kwallet)
+		-DUSE_LIBSECRET=$(usex gnome-keyring)
+		-DUSE_LUA=$(usex lua)
+		-DUSE_MAP=$(usex geolocation)
+		-DUSE_NLS=$(usex nls)
+		-DUSE_OPENCL=$(usex opencl)
+		-DUSE_OPENEXR=$(usex openexr)
+		-DUSE_OPENJPEG=$(usex jpeg2k)
+		-DUSE_OPENMP=$(usex openmp)
+		-DUSE_PORTMIDI=$(usex midi)
+		-DUSE_SDL2=$(usex gamepad)
+		-DUSE_WEBP=$(usex webp)
+		-DWANT_JSON_VALIDATION=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# This USE flag is masked for -9999
+	use doc && dodoc "${DISTDIR}"/${PN}-usermanual-${DOC_PV}.*.pdf
+
+	if use nls; then
+		for lang in ${LANGS} ; do
+			if ! use l10n_${lang}; then
+				rm -r "${ED}"/usr/share/locale/${lang/-/_} || die
+			fi
+		done
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog
+	elog "When updating a major version,"
+	elog "please bear in mind that your edits will be preserved during this process,"
+	elog "but it will not be possible to downgrade any more."
+	elog
+	ewarn "It will not be possible to downgrade!"
+	ewarn
+}
diff --git a/media-gfx/darktable/metadata.xml b/media-gfx/darktable/metadata.xml
index c20058315b0b..bf52d8de9b94 100644
--- a/media-gfx/darktable/metadata.xml
+++ b/media-gfx/darktable/metadata.xml
@@ -15,6 +15,7 @@
 		<flag name="gamepad">Support using game controllers as input devices</flag>
 		<flag name="geolocation">Enable geotagging support</flag>
 		<flag name="gmic">Use the G'MIC image-processing framework (<pkg>media-gfx/gmic</pkg>), e.g. to support Colour LUTs compressed using their compression scheme</flag>
+		<flag name="heif">Enable support for ISO/IEC 23008-12:2017 HEIF/HEIC image format using <pkg>media-libs/libheif</pkg></flag>
 		<flag name="kwallet">Enable encrypted storage of passwords with <pkg>kde-frameworks/kwallet</pkg></flag>
 		<flag name="lto">Enable link-time optimisations in the RawSpeed library</flag>
 		<flag name="midi">Support using MIDI input devices such as Behringer X-Touch Mini, Arturia Beatstep or Korg nanoKONTROL2, as input devices</flag>