mail-filter/courier-pythonfilter: properly install config files

As python's packaging no longer allows installing outside its
module dir, we have to manually place the configs into /etc.

See https://github.com/gordonmessmer/courier-pythonfilter/issues/8

Signed-off-by: Hanno Böck <hanno@gentoo.org>

1 files changed, 29 insertions, 0 deletions

diff --git a/mail-filter/courier-pythonfilter/courier-pythonfilter-3.0.6-r1.ebuild b/mail-filter/courier-pythonfilter/courier-pythonfilter-3.0.6-r1.ebuild
new file mode 100644
index 000000000000..e55bd80615cf
--- /dev/null
+++ b/mail-filter/courier-pythonfilter/courier-pythonfilter-3.0.6-r1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+PYPI_NO_NORMALIZE=1
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python filtering architecture for the Courier MTA"
+HOMEPAGE="https://pypi.org/project/courier-pythonfilter/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="mail-mta/courier"
+
+python_install() {
+	distutils-r1_python_install
+	rm -rf "${D}$(python_get_sitedir)/etc" || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc
+	doins pythonfilter.conf pythonfilter-modules.conf
+}