kde-plasma/plasma-firewall: 5.26.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index ab614597fd0e..67d7f50e1214 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.25.5.tar.xz 357380 BLAKE2B 37dcd280306a4b7674a78ce8a74f01ea804a136174725d228370427567b851dff6eeed01aaa687014d565c19694908f0f9aba4f811da8c7d8d2208b6d0250581 SHA512 b6059e732f34af49263ff0beecb9f11894420166a60ef0ebdce38fff9bb472c1c6d058f4ae6d3cae8194c5b6efe127971e6057564e887317250a4691df73e1e0
 DIST plasma-firewall-5.26.4.tar.xz 358564 BLAKE2B b75edff3c104ef0e4aab3efe87ccd78c3a627aa7bef377af2bc366927115deb3986d52c95161d36ed61da452d4a9f16aef3c37018b0ee6e30a69a00a0a582896 SHA512 a4c574c0eb23e52316bbc85f647db96f062982fd8ca7ca7751b85d570690dca353e2cf6b312c729d66993bcb2ab194fd8b9e00834c98c680e032e2046cb0c6a4
+DIST plasma-firewall-5.26.5.tar.xz 358560 BLAKE2B 5a5a15045414879bc155eafdec60941ba62559129cad5eb6b026e98973fa39ca7169e599190e04de5f9a7097727a98283e810f046265da122fd35f87c2be3659 SHA512 cd9ec0eef5511cab11211aac2ed14b593638386d41ce6e378053699418ac8c4698aa42d637763dae56668a794d1f877213a328dee86fe7777b909b3932bfb755
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.26.5.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.26.5.ebuild
new file mode 100644
index 000000000000..3df2884f2209
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.26.5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}