kde-apps/umbrello: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/kde-apps/umbrello/Manifest b/kde-apps/umbrello/Manifest
index 96769a301aa3..86a2d1fd2ece 100644
--- a/kde-apps/umbrello/Manifest
+++ b/kde-apps/umbrello/Manifest
@@ -1 +1,2 @@
 DIST umbrello-20.12.3.tar.xz 5555804 BLAKE2B a923d4f4d952dbbfc8166b2ca2bff990a4ad8652762277c3f16d4c37ffd26c1761a3480d45640c2821b0e85633158a90d82358afedc11fae98b2d5e58d0e7f57 SHA512 619d83ffd307be57fc8f3dc935dde6bdeffc60186ab675b8f2e530bb6a125ec1e03fccc49772c6d4cc120b3280e56f28344cba2627c3b955f9cd338cd071da6a
+DIST umbrello-21.04.0.tar.xz 5568700 BLAKE2B c68487e8e5db3da201003d923ac7f717f749110b22efe08d7e7476a7ddc79d1aadd8863a3ed7ee78dbd838d4e0afbfbe655925818fec72cfa4c9ba02f53d1b26 SHA512 b14a90afea1e33a4c5c3a3b8f9a9589a845afa278c8e3e165542be36ddb1ecd28abe4f678c753e34a85e92fba65d98f0f9be34b1976d1c52edfbfff87432e379
diff --git a/kde-apps/umbrello/umbrello-21.04.0.ebuild b/kde-apps/umbrello/umbrello-21.04.0.ebuild
new file mode 100644
index 000000000000..20c68b3b625a
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-21.04.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.80.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/en/umbrello https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.08.3-no-qtwebkit.patch
+	"${FILESDIR}"/${PN}-20.08.3-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DBUILD_APIDOC=OFF
+		-DBUILD_KF5=ON
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}