kde-apps/umbrello: 22.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/kde-apps/umbrello/Manifest b/kde-apps/umbrello/Manifest
index af4cf485c5bf..0e2ecfbb3166 100644
--- a/kde-apps/umbrello/Manifest
+++ b/kde-apps/umbrello/Manifest
@@ -1 +1,2 @@
 DIST umbrello-22.04.3.tar.xz 5674976 BLAKE2B 2e314adc1ea1466c332b34dd861d5eba7a1f09a3363a2c658c9459c1006d39a220fa6bbd80ef1bba393007fc7eb7a10a0b3dba48360a022c65d8eac6a2d86aed SHA512 8c44eca651bef1f4b5022a6c4ef8b6e58277ae4694a1797b75465c6d0cf3936c0f5f3bc2c1d6344885b2a3b0e4f9247b76a63432099590396da634457d56e59e
+DIST umbrello-22.08.0.tar.xz 5681300 BLAKE2B 3fe412fa967ea6b4f0f8131830b53cd8a4c84d2a2f76a6b321a85dd338c10e8c9ca08682e02cae02b2fd7b3823a631ae74154fdae69ab602c1c9e9473bf0f2b3 SHA512 04a2f7a7a0a1be2e00a6d9532692dac29f82808929dbc94f7db67d89a6c319c5a1a912560ed39f9dd968bcec234fea66d7f4db242dc57c9e75d8f361e8501e86
diff --git a/kde-apps/umbrello/umbrello-22.08.0.ebuild b/kde-apps/umbrello/umbrello-22.08.0.ebuild
new file mode 100644
index 000000000000..ca64253f7e40
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-22.08.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/ https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.08.3-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DBUILD_APIDOC=OFF
+		-DBUILD_KF5=ON
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}