kde-apps/k3b: 23.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index 0261bc3468e2..f248d6161f0c 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,2 +1,3 @@
 DIST k3b-23.04.3.tar.xz 10951208 BLAKE2B f1361119e4c826ed31e6d9edee1d0c7c025ec7c9e3c04cde09174a84367cf604f3b98065939a06189ac99ee75b5375550396e02b44344ea7c71553abbcf4235f SHA512 de2d1eb7176226751658af688427cd2d2daf038d0dd5941769639a08ddf22064b062b3709f07e72d788c1f19cb15250d8d240ed0edb148e21dcdf4454fcbbcf6
 DIST k3b-23.08.1.tar.xz 10966764 BLAKE2B e8724dd61877a4304ef76921f66668b6a2edce48fab047a7232003fae709f6929eb30f8ddb06cebb093367f46f8e3b1ad5935d9635c3fefad1f1bbd4dbc47d3f SHA512 5b858836896cad6763203ac4577c9b949d0e732190de5d60587a4c4633faa3854f975b8a8fcd826a6d22f4fdc80052d2bab04a8718e855815e0c38bc29e0fb3b
+DIST k3b-23.08.2.tar.xz 10966768 BLAKE2B 52622d61c11ecdbe85eb5e3830ad2e9413a415df183419c9605cef22da6ba36a58086497d80115fbf634ffb1253bf958dc34ddb78998d16f99fb451aee0d269d SHA512 718e03c88a0bb52bd7cf6c1e78d9bd1ed44b90b1bcaadf7861edd6d5ac96e99c2da366b011561f99b2e473fdd999ac277ababd93990d52a68d6af19454ae970f
diff --git a/kde-apps/k3b/k3b-23.08.2.ebuild b/kde-apps/k3b/k3b-23.08.2.ebuild
new file mode 100644
index 000000000000..47a02d8741fe
--- /dev/null
+++ b/kde-apps/k3b/k3b-23.08.2.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/k3b/ https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="dvd ffmpeg flac lame mad musepack sndfile sox taglib vcd vorbis webengine"
+
+REQUIRED_USE="flac? ( taglib ) lame? ( taglib ) sox? ( taglib )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-apps/libkcddb-${PVCUT}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib?]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( >=media-libs/flac-1.2:=[cxx] )
+	lame? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5[widgets] )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	app-cdr/cdrtools
+	dev-libs/libburn
+	media-sound/cdparanoia
+	dvd? ( >=app-cdr/dvd+rw-tools-7 )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+PATCHES=( "${FILESDIR}/${PN}-23.04.2-disable-transcode.patch" ) # bugs 891585, 906526
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=ON
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex lame)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	elog
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+}