gui-wm/sway: EAPI bump, minor improvements

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

2 files changed, 134 insertions, 11 deletions

diff --git a/gui-wm/sway/sway-1.7-r2.ebuild b/gui-wm/sway/sway-1.7-r2.ebuild
new file mode 100644
index 000000000000..c0c995944c3c
--- /dev/null
+++ b/gui-wm/sway/sway-1.7-r2.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature
+
+DESCRIPTION="i3-compatible Wayland window manager"
+HOMEPAGE="https://swaywm.org"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	MY_PV=${PV/_rc/-rc}
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="grimshot +man +swaybar +swaynag tray wallpapers X"
+
+DEPEND="
+	>=dev-libs/json-c-0.13:0=
+	>=dev-libs/libinput-1.6.0:0=
+	sys-auth/seatd:=
+	dev-libs/libpcre
+	>=dev-libs/wayland-1.20.0
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	x11-libs/pixman
+	media-libs/mesa[gles2,libglvnd(+)]
+	swaybar? ( x11-libs/gdk-pixbuf:2 )
+	tray? ( || (
+		sys-apps/systemd
+		sys-auth/elogind
+		sys-libs/basu
+	) )
+	wallpapers? ( gui-apps/swaybg[gdk-pixbuf(+)] )
+	X? ( x11-libs/libxcb:0= )
+"
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+="~gui-libs/wlroots-9999:=[X?]"
+else
+	DEPEND+="
+		>=gui-libs/wlroots-0.15:=[X?]
+		<gui-libs/wlroots-0.16:=[X?]
+	"
+fi
+RDEPEND="
+	x11-misc/xkeyboard-config
+	grimshot? (
+		app-misc/jq
+		gui-apps/grim
+		gui-apps/slurp
+		gui-apps/wl-clipboard
+		x11-libs/libnotify
+	)
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.24
+	>=dev-util/meson-0.60.0
+	virtual/pkgconfig
+"
+if [[ ${PV} == 9999 ]]; then
+	BDEPEND+="man? ( ~app-text/scdoc-9999 )"
+else
+	BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
+fi
+REQUIRED_USE="tray? ( swaybar )"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature man man-pages)
+		$(meson_feature tray)
+		$(meson_feature X xwayland)
+		$(meson_feature swaybar gdk-pixbuf)
+		$(meson_use swaynag)
+		$(meson_use swaybar)
+		$(meson_use wallpapers default-wallpaper)
+		-Dfish-completions=true
+		-Dzsh-completions=true
+		-Dbash-completions=true
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use grimshot; then
+		doman contrib/grimshot.1
+		dobin contrib/grimshot
+	fi
+}
+
+pkg_postinst() {
+	optfeature_header "There are several packages that may be useful with sway:"
+	optfeature "wallpaper utility" gui-apps/swaybg
+	optfeature "idle management utility" gui-apps/swayidle
+	optfeature "simple screen locker" gui-apps/swaylock
+	optfeature "lightweight notification daemon" gui-apps/mako
+	echo
+	einfo "For a list of additional addons and tools usable with sway please"
+	einfo "visit the offical wiki at:"
+	einfo "https://github.com/swaywm/sway/wiki/Useful-add-ons-for-sway"
+	einfo "Please note that some of them might not (yet) available on gentoo"
+}
diff --git a/gui-wm/sway/sway-9999.ebuild b/gui-wm/sway/sway-9999.ebuild
index 3c0073c3c363..8b8ee2335dc1 100644
--- a/gui-wm/sway/sway-9999.ebuild
+++ b/gui-wm/sway/sway-9999.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit meson
+inherit meson optfeature
 
 DESCRIPTION="i3-compatible Wayland window manager"
 HOMEPAGE="https://swaywm.org"
@@ -20,7 +20,7 @@ fi
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="grimshot +man +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag tray wallpapers X"
+IUSE="grimshot +man +swaybar +swaynag tray wallpapers X"
 
 DEPEND="
 	>=dev-libs/json-c-0.13:0=
@@ -34,23 +34,20 @@ DEPEND="
 	x11-libs/pixman
 	media-libs/mesa[gles2,libglvnd(+)]
 	swaybar? ( x11-libs/gdk-pixbuf:2 )
-	swaybg? ( gui-apps/swaybg )
-	swayidle? ( gui-apps/swayidle )
-	swaylock? ( gui-apps/swaylock )
 	tray? ( || (
 		sys-apps/systemd
 		sys-auth/elogind
 		sys-libs/basu
 	) )
-	wallpapers? ( x11-libs/gdk-pixbuf:2[jpeg] )
+	wallpapers? ( gui-apps/swaybg[gdk-pixbuf(+)] )
 	X? ( x11-libs/libxcb:0= )
 "
 if [[ ${PV} == 9999 ]]; then
-	DEPEND+="~gui-libs/wlroots-9999:=[X=]"
+	DEPEND+="~gui-libs/wlroots-9999:=[X?]"
 else
 	DEPEND+="
-		>=gui-libs/wlroots-0.16:=[X=]
-		<gui-libs/wlroots-0.17:=[X=]
+		>=gui-libs/wlroots-0.16:=[X?]
+		<gui-libs/wlroots-0.17:=[X?]
 	"
 fi
 RDEPEND="
@@ -74,7 +71,7 @@ if [[ ${PV} == 9999 ]]; then
 else
 	BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
 fi
-REQUIRED_USE="grimshot? ( swaymsg )"
+REQUIRED_USE="tray? ( swaybar )"
 
 src_configure() {
 	local emesonargs=(
@@ -101,3 +98,16 @@ src_install() {
 		dobin contrib/grimshot
 	fi
 }
+
+pkg_postinst() {
+	optfeature_header "There are several packages that may be useful with sway:"
+	optfeature "wallpaper utility" gui-apps/swaybg
+	optfeature "idle management utility" gui-apps/swayidle
+	optfeature "simple screen locker" gui-apps/swaylock
+	optfeature "lightweight notification daemon" gui-apps/mako
+	echo
+	einfo "For a list of additional addons and tools usable with sway please"
+	einfo "visit the offical wiki at:"
+	einfo "https://github.com/swaywm/sway/wiki/Useful-add-ons-for-sway"
+	einfo "Please note that some of them might not (yet) available on gentoo"
+}