games-strategy/naev: add 0.10.2

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index 32ea2e423dc5..caecdd984511 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1 +1,2 @@
 DIST naev-0.10.1-source.tar.xz 444805652 BLAKE2B 5855608c14ba2d32824d14867c60b91321dba0be44e9857f795db308353428c6c0fcf891dc099221695e94479f6bffbc309e97380751d70b55f2060f889a9144 SHA512 91a1f3909462cb00a366a5006a1ea5da289f10dfe8ec3a5b8ab21bc281a74742724bb287fc8ffc31277e38b0f4c778812b800eb814f399b480ba72deb957249c
+DIST naev-0.10.2-source.tar.xz 444824076 BLAKE2B 8f45c279c1077a50a2951d4a1a5ebd035e3980b05097c0631b02560597ab94f7e8eca4a76a280c348df709c9a5e75c352ecfb02550de9ec53bf987c6e1257cc8 SHA512 8e9eff735f12bf308d52ae3bae10a83cfbd7e80d614b366d53c7f2d37826f5b9158f430324d7106f8c2c750888c09fe09f0a97d1f6af31e50b4f77bdf456025a
diff --git a/games-strategy/naev/naev-0.10.2.ebuild b/games-strategy/naev/naev-0.10.2.ebuild
new file mode 100644
index 000000000000..f66552cc380e
--- /dev/null
+++ b/games-strategy/naev/naev-0.10.2.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{8..11} )
+inherit lua-single meson python-any-r1 virtualx xdg
+
+DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="https://naev.org/"
+SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
+
+LICENSE="
+	GPL-3+
+	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
+	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+# dlopen: libglvnd
+RDEPEND="
+	${LUA_DEPS}
+	dev-games/physfs
+	dev-libs/libpcre2:=
+	dev-libs/libunibreak:=
+	dev-libs/libxml2
+	media-libs/freetype:2
+	media-libs/libglvnd
+	media-libs/libsdl2[joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	media-libs/sdl2-image[png,webp]
+	net-libs/enet:1.3=
+	sci-libs/cholmod
+	sci-libs/cxsparse
+	sci-libs/openblas
+	sci-libs/suitesparse
+	sci-mathematics/glpk:=
+	virtual/libintl"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-games/physfs[zip]
+		media-libs/libsdl2[X]
+		media-libs/mesa[llvm]
+	)"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/gettext
+	doc? (
+		app-doc/doxygen
+		dev-lua/ldoc
+		media-gfx/graphviz
+	)"
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# use eclass' generated lua.pc first rather than as fallback
+	sed -i "s/'lua51'/'lua'/" meson.build || die
+
+	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369),
+	# mesa[llvm] should ensure software rendering will work
+	sed -i "/subdir('glcheck')/d" test/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc docs_c)
+		$(meson_feature doc docs_lua)
+		$(meson_feature lua_single_target_luajit luajit)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	local DOCS=( CHANGELOG Readme.md )
+	meson_src_install
+
+	if use doc; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
+		rm -r "${ED}"/usr/doc || die
+	fi
+
+	rm -r "${ED}"/usr/share/doc/naev || die
+}