games-board/pychess: version bump to 0.99.3

Following fixes on the way:

 - update copyright header
 - use xdg-utils instead of fdo-mime eclass
 - update to python 3

The gnome2-utils eclass currently does not support EAPI 7.

Closes: https://bugs.gentoo.org/664594
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Matthias Maier <tamiko@gentoo.org>

1 files changed, 71 insertions, 0 deletions

diff --git a/games-board/pychess/pychess-0.99.3.ebuild b/games-board/pychess/pychess-0.99.3.ebuild
new file mode 100644
index 000000000000..cda42d081007
--- /dev/null
+++ b/games-board/pychess/pychess-0.99.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit gnome2-utils distutils-r1 xdg-utils
+
+DESCRIPTION="A chess client for Gnome"
+HOMEPAGE="http://pychess.org/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gstreamer"
+
+DEPEND="
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	gnome-base/librsvg:2
+	x11-libs/gtksourceview:3.0
+	x11-libs/pango
+	x11-themes/adwaita-icon-theme
+	gstreamer? (
+		dev-python/gst-python:1.0
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0 )
+"
+RDEPEND=${DEPEND}
+
+python_install() {
+	distutils-r1_python_install
+
+	# bug 487706
+	sed -i \
+		-e "s/@PYTHON@/${EPYTHON}/" \
+		"${ED%/}/$(python_get_sitedir)"/${PN}/Players/engineNest.py || die
+}
+
+python_install_all() {
+	DOCS="AUTHORS README.md" \
+		distutils-r1_python_install_all
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+src_install() {
+	distutils-r1_src_install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+}