proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 72 insertions, 0 deletions

diff --git a/dev-util/trace-cmd/trace-cmd-2.5.1.ebuild b/dev-util/trace-cmd/trace-cmd-2.5.1.ebuild
new file mode 100644
index 000000000000..5bb6a80bba44
--- /dev/null
+++ b/dev-util/trace-cmd/trace-cmd-2.5.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=(python2_7)
+
+inherit eutils toolchain-funcs linux-info python-single-r1
+
+DESCRIPTION="User-space front-end for Ftrace"
+HOMEPAGE="https://git.kernel.org/cgit/linux/kernel/git/rostedt/trace-cmd.git"
+SRC_URI="mirror://gentoo/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc gtk python udis86"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )
+	udis86? ( dev-libs/udis86 )
+	gtk? (
+		${PYTHON_DEPS}
+		dev-python/pygtk:2[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	sys-kernel/linux-headers
+	python? (
+		virtual/pkgconfig
+		dev-lang/swig
+	)
+	gtk? ( virtual/pkgconfig )
+	doc? ( app-text/asciidoc )"
+
+CONFIG_CHECK="
+	~TRACING
+	~FTRACE
+	~BLK_DEV_IO_TRACE"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-makefile.patch
+	epatch_user
+}
+
+src_configure() {
+	MAKEOPTS+=" prefix=/usr libdir=$(get_libdir) CC=$(tc-getCC) AR=$(tc-getAR)"
+
+	if use python; then
+		MAKEOPTS+=" PYTHON_VERS=${EPYTHON//python/python-}"
+		MAKEOPTS+=" python_dir=$(python_get_sitedir)/${PN}"
+	else
+		MAKEOPTS+=" NO_PYTHON=1"
+	fi
+
+	use udis86 || MAKEOPTS+=" NO_UDIS86=1"
+}
+
+src_compile() {
+	emake all_cmd
+	use doc && emake doc
+	use gtk && emake -j1 gui
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	use doc && emake DESTDIR="${D}" install_doc
+	use gtk && emake DESTDIR="${D}" install_gui
+}