dev-util/rizin: add 0.6.3

Signed-off-by: John Helmert III <ajak@gentoo.org>

2 files changed, 99 insertions, 0 deletions

diff --git a/dev-util/rizin/Manifest b/dev-util/rizin/Manifest
index 11a47a0cdde8..1d6bbfad14ab 100644
--- a/dev-util/rizin/Manifest
+++ b/dev-util/rizin/Manifest
@@ -1,2 +1,3 @@
 DIST rizin-src-v0.6.2.tar.xz 15409072 BLAKE2B 9e90b07b5a3a5196e68e7c283dcfa214449e9cf1099c90b80a4e3712997bd6f28d5682de01c6f2b6ccafa749e74a4a9a8f7e6e0a313e926779394322a52b14ff SHA512 2b75ebd1c94dd560bb48ffaf8cb56d765ceafd00a3a878f0ae8802a51f398202c501db4c2ec2caefa89a770d4e674743ff5b56fd21f06bf99d9bac4753580dce
+DIST rizin-src-v0.6.3.tar.xz 15411052 BLAKE2B 4ddde26dc2541917e1d16f38339bf1467b2148524a1365d739c417857ee856ecb7fbc9210a0f3b562a429c962e31f637bb88a0c0817f42a59868ed3093b0e902 SHA512 031ae1c5b43237d55b3e48d825d4bd9cda16a4a84a47464eb1745a02265a1412e2864345595c0dca7f8ea0cb348fe9760ea424556ff6b915ac8014a7f410b03c
 DIST rizin-testbins-903588ed69d7717069955322b31dad5e666b338a.tar.gz 181644100 BLAKE2B ea491bea61a6d17fa2727e1b08b810be2bb99d05cf2afa4e97dc440a69a4fd376a39c25c6e86e9e2d499732b55e7c75e5eef39adef84f571e48d147e410d04e5 SHA512 fffef043d76440976e02e2b890138f57df849f507c0a7a48bd97b421fc1683e73696c50b6daddf906a53685eccfd7346e25881d3d498417e4e55b97ef56b8317
diff --git a/dev-util/rizin/rizin-0.6.3.ebuild b/dev-util/rizin/rizin-0.6.3.ebuild
new file mode 100644
index 000000000000..6061d10b5c4a
--- /dev/null
+++ b/dev-util/rizin/rizin-0.6.3.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+# This is the commit that the CI for the release commit used
+BINS_COMMIT="903588ed69d7717069955322b31dad5e666b338a"
+
+inherit meson python-any-r1
+
+DESCRIPTION="reverse engineering framework for binary analysis"
+HOMEPAGE="https://rizin.re/"
+
+SRC_URI="mirror+https://github.com/rizinorg/rizin/releases/download/v${PV}/rizin-src-v${PV}.tar.xz
+	test? ( https://github.com/rizinorg/rizin-testbins/archive/${BINS_COMMIT}.tar.gz -> rizin-testbins-${BINS_COMMIT}.tar.gz )"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+LICENSE="Apache-2.0 BSD LGPL-3 MIT"
+SLOT="0/${PV}"
+IUSE="test"
+
+# Need to audit licenses of the binaries used for testing
+RESTRICT="test? ( fetch ) !test? ( test )"
+
+# TODO: unbundle dev-libs/blake3
+RDEPEND="
+	app-arch/lz4:0=
+	app-arch/xz-utils
+	>=dev-libs/capstone-5:0=
+	dev-libs/libmspack
+	dev-libs/libzip:0=
+	dev-libs/openssl:0=
+	>=dev-libs/tree-sitter-0.19.0
+	dev-libs/xxhash
+	sys-apps/file
+	sys-libs/zlib:0=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.4.0-never-rebuild-parser.patch"
+	"${FILESDIR}/${PN}-0.5.2-find-tree-sitter-parser.patch"
+)
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+src_prepare() {
+	default
+
+	local py_to_mangle=(
+		librz/core/cmd_descs/cmd_descs_generate.py
+		sys/clang-format.py
+		test/fuzz/scripts/fuzz_rz_asm.py
+		test/scripts/gdbserver.py
+	)
+
+	python_fix_shebang "${py_to_mangle[@]}"
+
+	# https://github.com/rizinorg/rizin/issues/3459
+	sed -ie '/dyld_chained_ptr_arm64e_auth/d' test/unit/test_bin_mach0.c || die
+
+	if use test; then
+		cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}/test/bins" || die
+		cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}" || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcli=enabled
+		-Duse_sys_capstone=enabled
+		-Duse_sys_libmspack=enabled
+		-Duse_sys_libzip=enabled
+		-Duse_sys_lz4=enabled
+		-Duse_sys_lzma=enabled
+		-Duse_sys_magic=enabled
+		# https://github.com/rizinorg/rizin/issues/3841
+		# -Duse_sys_openssl=enabled
+		-Duse_sys_tree_sitter=enabled
+		-Duse_sys_xxhash=enabled
+		-Duse_sys_zlib=enabled
+
+		$(meson_use test enable_tests)
+		$(meson_use test enable_rz_test)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# We can select running either unit or integration tests, or all of
+	# them by not passing --suite. According to upstream, integration
+	# tests are more fragile and unit tests are sufficient for testing
+	# packaging, so only run those.
+	meson_src_test --suite unit
+}