dev-tex/latexdiff: Version bump (v1.3.1.1)

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-tex/latexdiff/latexdiff-1.3.1.1.ebuild b/dev-tex/latexdiff/latexdiff-1.3.1.1.ebuild
new file mode 100644
index 000000000000..2926345b876e
--- /dev/null
+++ b/dev-tex/latexdiff/latexdiff-1.3.1.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Compare two latex files and mark up significant differences"
+HOMEPAGE="https://www.ctan.org/tex-archive/support/latexdiff/ https://github.com/ftilmann/latexdiff/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ftilmann/latexdiff.git"
+else
+	SRC_URI="https://github.com/ftilmann/latexdiff/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-lang/perl-5.8
+	virtual/latex-base
+	dev-texlive/texlive-plaingeneric
+	dev-perl/Algorithm-Diff
+"
+DEPEND="${RDEPEND}
+	dev-perl/Pod-LaTeX
+"
+BDEPEND="
+	test? ( app-shells/tcsh )
+"
+
+src_compile() {
+	export VARTEXFONTS="${T}/fonts"
+	PATH="${S}/dist:${PATH}" emake -j1 distribution
+}
+
+src_test() {
+	emake test
+}
+
+src_install() {
+	cd dist || die
+	dobin latexdiff latexrevise latexdiff-vc
+	doman latexdiff.1 latexrevise.1 latexdiff-vc.1
+	dodoc README doc/latexdiff-man.pdf
+}