proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-scheme/racket/racket-5.3.2.ebuild b/dev-scheme/racket/racket-5.3.2.ebuild
new file mode 100644
index 000000000000..e5aeb2adc095
--- /dev/null
+++ b/dev-scheme/racket/racket-5.3.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+# for live ebuilds uncomment inherit git, comment SRC_URI and empty KEYWORDS
+
+inherit eutils
+#inherit git-2
+
+DESCRIPTION="Racket is a general-purpose programming language with strong support for domain-specific languages"
+HOMEPAGE="http://racket-lang.org/"
+SRC_URI="http://download.racket-lang.org/installers/${PV}/${PN}/${P}-src-unix.tgz"
+#SRC_URI="http://pre.racket-lang.org/installers/plt-${PV}-src-unix.tgz"
+EGIT_REPO_URI="git://git.racket-lang.org/plt.git"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="backtrace cairo doc futures jit places plot threads X"
+
+RDEPEND="dev-db/sqlite:3 X? ( x11-libs/cairo[X] ) virtual/libffi"
+
+DEPEND="${RDEPEND} !dev-tex/slatex"
+
+EGIT_SOURCEDIR="${WORKDIR}/${P}"
+S="${WORKDIR}/${P}/src"
+
+src_prepare() {
+	#remove bundled libraries
+	rm -rf foreign/libffi/
+
+	sed -e "s,docdir=\"\${datadir}/${PN}/doc,docdir=\"\${datadir}/doc/${PF}," -i configure || die
+}
+
+src_configure() {
+# according to vapier, we should use the bundled libtool
+# such that we don't preclude cross-compile. Thus don't use
+# --enable-lt=/usr/bin/libtool
+	econf \
+		$(use_enable X gracket) \
+		$(use_enable plot) \
+		$(use_enable doc docs) \
+		--enable-shared \
+		$(use_enable jit) \
+		--enable-foreign \
+		$(use_enable places) \
+		$(use_enable futures) \
+		$(use_enable backtrace) \
+		$(use_enable threads pthread) \
+		--disable-perl \
+		$(use_with X x)
+}
+
+src_compile() {
+	emake || die
+}
+
+src_install() {
+	# deal with slatex
+	insinto /usr/share/texmf/tex/latex/slatex/
+	doins ../collects/slatex/slatex.sty
+
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	if use X; then
+		newicon ../collects/icons/PLT-206.png drracket.png
+		make_desktop_entry drracket "DrRacket" drracket "Development"
+	fi
+}