dev-qt/qtconnectivity: add 6.7.1

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-qt/qtconnectivity/Manifest b/dev-qt/qtconnectivity/Manifest
index 09b3b7344b19..caafe55e4b1c 100644
--- a/dev-qt/qtconnectivity/Manifest
+++ b/dev-qt/qtconnectivity/Manifest
@@ -1 +1,2 @@
 DIST qtconnectivity-everywhere-src-6.7.0.tar.xz 1060904 BLAKE2B 83669930846e57495c193b467c8a004eb2a61017934b5f1c8ecb39de24f538b40671dc06ec558e0809e131f008abc16826a246abbe5acee59ebaf69849070652 SHA512 bbdb6798a9cca5ec523d0f06aa3e1ea0024e4c7bd5cba765ad87b7b2f40ec59bd2a557bb45224bb3490c818292ccf04283f7c5d47723d95d83f2edf85c214b78
+DIST qtconnectivity-everywhere-src-6.7.1.tar.xz 1061900 BLAKE2B 30cb15ba6a0e08fccfd0f3ce9a9ec36a0902e3fa15bdd0791e166371c6baa31438c141c7bf5c57de0287eeee04bae87aaaf4800eeaa3062ab23d541e577cce3a SHA512 28496a2a7338f71bb51fbd8fa1b23e4e2e14e6fefc6249ce0eeae8d19b7740a70eed1c312c5d5a79344330001592acd4048c134382cdc168cf4d30e9760dbdc2
diff --git a/dev-qt/qtconnectivity/qtconnectivity-6.7.1.ebuild b/dev-qt/qtconnectivity/qtconnectivity-6.7.1.ebuild
new file mode 100644
index 000000000000..de07cbfd1ffe
--- /dev/null
+++ b/dev-qt/qtconnectivity/qtconnectivity-6.7.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Bluetooth and NFC support library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+fi
+
+IUSE="+bluetooth nfc smartcard"
+REQUIRED_USE="|| ( bluetooth nfc )"
+
+RDEPEND="
+	~dev-qt/qtbase-${PV}:6[network]
+	bluetooth? (
+		~dev-qt/qtbase-${PV}:6[dbus]
+		net-wireless/bluez:=
+	)
+	nfc? (
+		smartcard? ( sys-apps/pcsc-lite )
+	)
+"
+DEPEND="${RDEPEND}"
+
+CMAKE_SKIP_TESTS=(
+	# most hardware tests are auto-skipped, but some still misbehave
+	# if bluez/hardware is available (generally tests here may not be
+	# very relevant without hardware, lists may need to be extended)
+	tst_qbluetoothlocaldevice
+	tst_qbluetoothserver
+	tst_qbluetoothservicediscoveryagent
+	tst_qbluetoothserviceinfo
+	tst_qlowenergycontroller
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	use bluetooth ||
+		sed -i '/add_subdirectory(bluetooth)/d' src/CMakeLists.txt || die
+	use nfc ||
+		sed -i '/add_subdirectory(nfc)/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(usev nfc $(qt_feature smartcard pcsclite))
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	# broken (unnecessary) symlink due to add_app() being used over add_tool()
+	use !bluetooth || rm -- "${ED}"/usr/bin/sdpscanner6 || die
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_BINDIR}"/bluetoothtestdevice
+			"${D}${QT6_BINDIR}"/bttestui
+			"${D}${QT6_BINDIR}"/qlecontroller-server
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}