dev-python/translate-toolkit: 2.5.1 version bump, python3_9

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index a9b67f3d9be8..bc3c8b99f9c2 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1 +1,2 @@
 DIST translate-toolkit-2.5.0.tar.gz 7679224 BLAKE2B 927b0dcfc0836ed2f2589d70f5789fc6d8b23a3e80bf4ef0054704ca12e4b5287a7e3b2a90992197bae6fc0acee1ea9d93a8eff05f6e5182f9269ca2aa9e5a66 SHA512 c4ff8fe9e7cc5b44a5448391ecbcfc454bf32d3794267e67824b020ca78cfbeba1283287a42f07859cd197a413fe8171ad5e31375f60fec77f334642ed2ad13e
+DIST translate-toolkit-2.5.1.tar.gz 5984081 BLAKE2B 55e158d0d354f181a4e23d9638306eb82bda0dd3133a507de682a54c4197d36ae6ad6bf3d733eb841d9406933407eb98c5874a13e55c7840a672971e87721d94 SHA512 57bdd7f824527955fde6db3a69ffadc27814336c6f792d08bb70e56e95a646d0366e8a3a48ac187ef62804f79dd8a61a4a0b76c8a28e57047c310fcfdf79e999
diff --git a/dev-python/translate-toolkit/translate-toolkit-2.5.1.ebuild b/dev-python/translate-toolkit/translate-toolkit-2.5.1.ebuild
new file mode 100644
index 000000000000..198e83e0ddd2
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-2.5.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/translate/translate/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc +html +ical +ini +subtitles +yaml"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	doc? ( >=dev-python/sphinx-3.0.2 )
+"
+DEPEND="
+	>=dev-python/six-1.11.0[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	# Prevent unwanted d'loading in doc build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" \
+		-e "/html_theme/ s/sphinx-bootstrap/classic/" \
+		-i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( "${S}"/docs/_build/html/. )
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	rm -Rf docs || die
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}