dev-python/redis-py: 3.3.11 + py38

Also drop dev-python/setuptools from DEPEND
as distutils-r1 already adds it (to BDEPEND) for us.
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.84, Repoman-2.3.20

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-python/redis-py/redis-py-3.3.11.ebuild b/dev-python/redis-py/redis-py-3.3.11.ebuild
new file mode 100644
index 000000000000..42add4480b6e
--- /dev/null
+++ b/dev-python/redis-py/redis-py-3.3.11.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="redis"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python client for Redis key-value store"
+HOMEPAGE="https://github.com/andymccurdy/redis-py"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=""
+DEPEND="test? (
+		dev-db/redis
+		dev-python/mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.7.0[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# Make sure that tests will be used from BUILD_DIR rather than cwd.
+	mv tests tests-hidden || die
+
+	# Correct local import patch syntax
+	sed \
+		-e 's:from .conftest:from conftest:' \
+		-e 's:from .test_pubsub:from test_pubsub:' \
+		-i tests-hidden/test_*.py \
+		|| die
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use test; then
+		cp -r tests-hidden "${BUILD_DIR}"/tests || die
+	fi
+}
+
+python_test() {
+	local sock="${T}/redis.sock"
+
+	"${EPREFIX}/usr/sbin/redis-server" - <<- EOF
+		daemonize yes
+		pidfile "${T}/redis.pid"
+		unixsocket ${sock}
+		EOF
+
+	PYTHONPATH="${S}:${S}/tests-hidden"
+	esetup.py test --verbose
+	kill $(<"${T}/redis.pid")
+}