dev-python/openstacksdk: Bump to 1.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 05eab448d174..ff208318fc6d 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1,2 +1,3 @@
 DIST openstacksdk-1.0.1.tar.gz 1118637 BLAKE2B d4677a3a5595bf871fc0b380f1cadfd56ebba14bc2255fcc6a6a4813c5c79807a1a0a76263844728f256704b2966b82be9bd6e968de9e7e85f411402f428cb78 SHA512 9871a262113b4396b3a5181e93d2e00312c5a80933c3ff6efa501a4b4d7d145985f54203eeb6e1f50c5593ba491b13a631b9293759e0615bf0eda393c247a4d3
 DIST openstacksdk-1.1.0.tar.gz 1141513 BLAKE2B f4c052ffa1efc36dfb355b50853d75ceddc5a3a361a8a8749bc51d55530dba465df451c7bf7154081130ca4d2d798e8c96b7230d4317bb9ebb96a9add410b501 SHA512 3c91a6a797c966bbf08dc51f013004c8ab9148dcd3a6fad4584fb40c256696a7ea02f241bc7ea1a3fbc56a7ec790dfd1900c0da54081c3d64f5077273d4e0835
+DIST openstacksdk-1.2.0.tar.gz 1160015 BLAKE2B d3ed5b9415715faf6d9cae225e2a8e7c3bd69907599fd2683f53e2070513a1f27aaae2d2f4aa40ada26ff819b5f8238c09e208243197165aa52f19776e53fc7c SHA512 4ce118b8b19b495f333f76cb416d2b4cc2c9ea835979cf67e83f6f7f40df13d29e19ed054a2f3ee469e6c5496da4a7a11193e4815b20195b28ba4c48263b6c1c
diff --git a/dev-python/openstacksdk/openstacksdk-1.2.0.ebuild b/dev-python/openstacksdk/openstacksdk-1.2.0.ebuild
new file mode 100644
index 000000000000..8bdeebd5a490
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-1.2.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.20[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib-metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus_client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}