dev-python/gitdb: Bump to 4.0.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/gitdb/Manifest b/dev-python/gitdb/Manifest
index 633690cf6a72..6db649cfa252 100644
--- a/dev-python/gitdb/Manifest
+++ b/dev-python/gitdb/Manifest
@@ -1 +1,2 @@
 DIST gitdb-4.0.5.tar.gz 392815 BLAKE2B ab0c557f1233ec6f454769c3d72d982c876cf7b8f67d8b36f9ed8a6a2ee4a04a7a22e1a7453aad0d128436e679940ffea9b2c1e6d433083634b47ffff08b396c SHA512 a3f562928a863121c4051663a0674aa94937527b2fc40a7f392d2913d4d1443bda278e2f7cf362d499389691d24a2d965ab89a6533d42a157db3ab629a377e83
+DIST gitdb-4.0.6.tar.gz 394670 BLAKE2B 579579981a4597fa540d7f2987fb24b81ee64066349ed479816ce010a94358af9d0821b8abb10886a5b6fdb56e158c398688690d9570495f041f974e3964b5a6 SHA512 b9cf964390cf18894c02e8854ef5099ef239bf4a43ae8659bf3def22a0fc35814c7416fd8b8312d9d0a170e5e0ea84380edbcac47cc435dc9ec1d98cf7f6463f
diff --git a/dev-python/gitdb/gitdb-4.0.6.ebuild b/dev-python/gitdb/gitdb-4.0.6.ebuild
new file mode 100644
index 000000000000..7b465b4d702f
--- /dev/null
+++ b/dev-python/gitdb/gitdb-4.0.6.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="GitDB is a pure-Python git object database"
+HOMEPAGE="
+	https://github.com/gitpython-developers/gitdb
+	https://pypi.org/project/gitdb/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-python/smmap-3.0.1[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-vcs/git
+	)"
+
+distutils_enable_tests nose
+
+src_prepare() {
+	# remove unnecessary version restriction
+	# https://github.com/gitpython-developers/gitdb/issues/67
+	sed -i -e '/smmap/s:,<4::' setup.py || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	local i
+
+	mkdir "${T}"/repo || die
+	cd "${T}"/repo || die
+
+	for (( i = 0; i < 2500; ++i )); do
+		echo "${i}" > file"${i}" || die
+	done
+
+	git init || die
+	git config user.email "you@example.com" || die
+	git config user.name "Your Name" || die
+	git add -A || die
+	git commit -q -m ".." || die
+	git clone --bare "${T}"/repo "${T}"/repo.git || die
+	cd "${S}" || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	#TRAVIS=1 disables performance tests which rely on the gitdb repo
+	local -x TRAVIS=1
+	local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}