dev-php/pecl-imagick: require USE="-debug" for dev-lang/php

Upstream knows about the issue but there hasn't been any movement on it
and the incompatibility breaks the test suite, so let's work around it.

Closes: https://bugs.gentoo.org/911661
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 34 insertions, 0 deletions

diff --git a/dev-php/pecl-imagick/pecl-imagick-3.7.0-r2.ebuild b/dev-php/pecl-imagick/pecl-imagick-3.7.0-r2.ebuild
new file mode 100644
index 000000000000..865604ba0dfb
--- /dev/null
+++ b/dev-php/pecl-imagick/pecl-imagick-3.7.0-r2.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PHP_EXT_NAME="imagick"
+USE_PHP="php8-0 php8-1 php8-2"
+
+# https://github.com/Imagick/imagick/issues/626
+PHP_EXT_NEEDED_USE="-debug"
+
+inherit php-ext-pecl-r3
+
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+DESCRIPTION="PHP wrapper for the ImageMagick library"
+HOMEPAGE="https://pecl.php.net/package/imagick https://github.com/Imagick/imagick"
+LICENSE="PHP-3.01"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+# imagemagick[-openmp] is needed wrt bug 547922 and upstream
+# https://github.com/Imagick/imagick#openmp
+RDEPEND="media-gfx/imagemagick:=[-openmp]"
+DEPEND="${RDEPEND}
+	test? ( media-gfx/imagemagick:=[hdri,jpeg,png,svg,truetype,xml] )"
+
+PHP_EXT_ECONF_ARGS="--with-imagick=${EPREFIX}/usr"
+
+src_install() {
+	php-ext-pecl-r3_src_install
+	php-ext-source-r3_addtoinifiles "imagick.skip_version_check" "1"
+}