dev-libs/libsolv: restore & version bump to 0.6.22

3 files changed, 113 insertions, 0 deletions

diff --git a/dev-libs/libsolv/Manifest b/dev-libs/libsolv/Manifest
new file mode 100644
index 000000000000..bbd89d1ab4f6
--- /dev/null
+++ b/dev-libs/libsolv/Manifest
@@ -0,0 +1 @@
+DIST libsolv-0.6.22.tar.gz 609489 SHA256 ee19f6ad3c3b1c905d0bf06ed89d98b82e64ac317f4d2e5cf105ac58316d877e SHA512 9f5a3fd7c8716a7313c8205edd9906973577f63340667674a5cbba29991bb159d9d1e2444bcd09debadbb23dc2a8e8f2b44a1575685dbb1031b5920c5eb6cbc1 WHIRLPOOL e5c4d0b2bdc86f9eefdb4906dbde64de080f129fbfc22f3fa00873c6837516cb5ef8e96b7d1919e0a18ca115b33125338245a693f451ee6faeb9949b51749ccb
diff --git a/dev-libs/libsolv/libsolv-0.6.22.ebuild b/dev-libs/libsolv/libsolv-0.6.22.ebuild
new file mode 100644
index 000000000000..1ad47f9ee93e
--- /dev/null
+++ b/dev-libs/libsolv/libsolv-0.6.22.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+USE_RUBY=( ruby23 )
+RUBY_OPTIONAL=yes
+
+inherit cmake-utils python-r1 ruby-ng perl-module multilib
+
+DESCRIPTION="Library for solving packages and reading repositories"
+HOMEPAGE="http://doc.opensuse.org/projects/libzypp/HEAD/ https://github.com/openSUSE/libsolv"
+SRC_URI="https://github.com/openSUSE/libsolv/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="bzip2 lzma perl python rpm ruby tcl"
+
+RDEPEND="
+	dev-libs/expat
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	lzma? ( app-arch/xz-utils )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	rpm? ( app-arch/rpm )
+	ruby? ( $(ruby_implementations_depend) )
+	tcl? ( dev-lang/tcl:0= )"
+DEPEND="${RDEPEND}
+	perl? ( dev-lang/swig:0 )
+	python? ( dev-lang/swig:0 )
+	ruby? ( dev-lang/swig:0 )
+	tcl? ( dev-lang/swig:0 )
+	sys-devel/gettext"
+
+# The ruby-ng eclass is stupid and breaks this for no good reason.
+S="${WORKDIR}/${P}"
+
+pkg_setup() {
+	use perl && perl_set_version
+	use ruby && ruby-ng_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# The python bindings are tightly integrated w/cmake.
+	sed -i \
+		-e 's: libsolv: -lsolv:g' \
+		bindings/python/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_VENDORDIRS=1
+		-DLIB="$(get_libdir)"
+		-DENABLE_PYTHON=0
+		$(cmake-utils_use_enable bzip2 BZIP2_COMPRESSION)
+		$(cmake-utils_use_enable lzma LZMA_COMPRESSION)
+		$(cmake-utils_use_enable perl PERL)
+		$(cmake-utils_use_enable rpm RPMDB)
+		$(cmake-utils_use_enable rpm RPMMD)
+		$(cmake-utils_use_enable ruby RUBY)
+		$(cmake-utils_use_enable tcl TCL)
+	)
+
+	cmake-utils_src_configure
+
+	if use python ; then
+		# python_foreach_impl will create a unique BUILD_DIR for
+		# us to run inside of, so no need to manage it ourselves.
+		mycmakeargs+=(
+			# Rework the bindings for a minor configure speedup.
+			-DENABLE_PYTHON=1
+			-DENABLE_{PERL,RUBY,TCL}=0
+		)
+		# Link against the common library so the bindings don't
+		# have to rebuild it.
+		LDFLAGS="-L${BUILD_DIR}/src ${LDFLAGS}" \
+		python_foreach_impl cmake-utils_src_configure
+	fi
+}
+
+pysolv_phase_func() {
+	BUILD_DIR="${BUILD_DIR}/bindings/python" \
+	cmake-utils_${EBUILD_PHASE_FUNC}
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use python && python_foreach_impl pysolv_phase_func
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use python && python_foreach_impl pysolv_phase_func
+	use perl && perl_delete_localpod
+}
diff --git a/dev-libs/libsolv/metadata.xml b/dev-libs/libsolv/metadata.xml
new file mode 100644
index 000000000000..cca76889721d
--- /dev/null
+++ b/dev-libs/libsolv/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="person">
+	<email>vapier@gentoo.org</email>
+</maintainer>
+<use>
+	<flag name="rpm">Enable support for RPM files</flag>
+</use>
+</pkgmetadata>