dev-libs/libpwquality: Version bump to 1.4.4

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/dev-libs/libpwquality/Manifest b/dev-libs/libpwquality/Manifest
index 073fba252299..5d32ae4b48d0 100644
--- a/dev-libs/libpwquality/Manifest
+++ b/dev-libs/libpwquality/Manifest
@@ -1 +1,2 @@
 DIST libpwquality-1.4.2.tar.bz2 423072 BLAKE2B 7f571e73ed4d12e6780dd47b6579aca3b7413eff23f9c11114ee2f95134893097b3cd183fcfc5482c96ca9bfdd1e137d4064062591f56b3998f3bf85768389eb SHA512 6f395e94797cc565edae6de8f4c7c60736d07ffa849c9878ec4d867f8cb7bea6f08bdd20501791dd05b02d487f8fea66a02a30841c7cea6e86b5903eaf685879
+DIST libpwquality-1.4.4.tar.bz2 426923 BLAKE2B 732e349a89b418d0b29d433551cd67e7b5f0daacb50ea73cfa7e45623801f6b559322645b4f4b0d741512964556d7e004d6a1c63b20e395c3c1b96923506e8bb SHA512 2d49b79105361663f009f7183fde9123e6f1e63bd678dfe5418143f611e763af8dd44374b826b3c22a00e721047c539741dc44d99a2289b9ab229791768d6e76
diff --git a/dev-libs/libpwquality/libpwquality-1.4.4.ebuild b/dev-libs/libpwquality/libpwquality-1.4.4.ebuild
new file mode 100644
index 000000000000..e12f25aba459
--- /dev/null
+++ b/dev-libs/libpwquality/libpwquality-1.4.4.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit pam python-r1 toolchain-funcs usr-ldscript
+
+DESCRIPTION="Library for password quality checking and generating random passwords"
+HOMEPAGE="https://github.com/libpwquality/libpwquality"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="pam python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+"
+RDEPEND="
+	>=sys-libs/cracklib-2.8:=[static-libs(+)?]
+	pam? ( sys-libs/pam )
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	# ensure pkgconfig files go in /usr
+	sed -e 's:\(pkgconfigdir *=\).*:\1 '${EPREFIX}/usr/$(get_libdir)'/pkgconfig:' \
+		-i src/Makefile.{am,in} || die "sed failed"
+	use python && python_copy_sources
+}
+
+src_configure() {
+	# Install library in /lib for pam
+	configuring() {
+		local sitedir
+		econf \
+			--libdir="${EPREFIX}/$(get_libdir)" \
+			$(use_enable pam) \
+			--with-securedir="${EPREFIX}/$(getpam_mod_dir)" \
+			$(use_enable python python-bindings) \
+			$(usex python "--with-pythonsitedir=$(use python && python_get_sitedir)" "") \
+			$(use_enable static-libs static)
+	}
+	if_use_python_python_foreach_impl configuring
+}
+
+src_compile() {
+	if_use_python_python_foreach_impl default
+}
+
+src_test() {
+	if_use_python_python_foreach_impl default
+}
+
+src_install() {
+	if_use_python_python_foreach_impl default
+	if use static-libs; then
+		# Do not install static libs in /lib
+		mkdir -p "${ED}/usr/$(get_libdir)"
+		mv "${ED}/$(get_libdir)/libpwquality.a" "${ED}/usr/$(get_libdir)/" || die
+		gen_usr_ldscript libpwquality.so
+	fi
+	find "${ED}" -name '*.la' -delete || die
+}
+
+if_use_python_python_foreach_impl() {
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
+}