dev-libs/libical: 3.0.9 version bump

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-libs/libical/Manifest b/dev-libs/libical/Manifest
index 481d2c743b14..4766dbe8f81f 100644
--- a/dev-libs/libical/Manifest
+++ b/dev-libs/libical/Manifest
@@ -1 +1,2 @@
 DIST libical-3.0.8.tar.gz 881462 BLAKE2B e31dd1c823be033abbecd0373af784f1f57e533df56ca91ea467deb02cdda2a719f22882195b639182b85fcf4e59d56229dbf601d2c909c2c91b355c32022622 SHA512 ce015e6d4c1c7cb4af7b45748ce8251c663f80f6a4357ddff6a97796642619abe882f4cadeca10cabeb1b25577869f436da15bca882e032eb3ff0475f6010d8b
+DIST libical-3.0.9.tar.gz 886500 BLAKE2B 66810ce13d70f9f1da62ff4d4c9dbff4953a644e939f55770cd4ca367293125b47590297b64a4b755cfb11315dfb4e77ad926390cde1c2d16847d24561288750 SHA512 4a9894d82776437cb2ef16df70bffb52da7b4fd57b52a4f6941430b3b1f9830829f0775fb495411f67393581bda1304b54c9f0031bc3d4ada56d2204900cb268
diff --git a/dev-libs/libical/libical-3.0.9.ebuild b/dev-libs/libical/libical-3.0.9.ebuild
new file mode 100644
index 000000000000..9ab9acb8a1be
--- /dev/null
+++ b/dev-libs/libical/libical-3.0.9.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+VALA_USE_DEPEND="vapigen"
+inherit cmake python-any-r1 vala
+
+DESCRIPTION="An implementation of basic iCAL protocols"
+HOMEPAGE="https://github.com/libical/libical"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="berkdb doc examples +glib +introspection static-libs test vala"
+
+REQUIRED_USE="introspection? ( glib ) vala? ( introspection )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	introspection? ( dev-libs/gobject-introspection )
+	test? ( ${PYTHON_DEPS} )
+	vala? ( $(vala_depend) )
+"
+COMMON_DEPEND="
+	dev-libs/icu:=
+	berkdb? ( sys-libs/db:= )
+	glib? ( dev-libs/glib:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	glib? ( dev-libs/libxml2:2 )
+"
+RDEPEND="${COMMON_DEPEND}
+	sys-libs/timezone-data
+"
+
+DOCS=(
+	AUTHORS ReadMe.txt ReleaseNotes.txt TEST THANKS TODO
+	doc/{AddingOrModifyingComponents,UsingLibical}.txt
+)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.4-tests.patch"
+	"${FILESDIR}/${PN}-3.0.5-pkgconfig-libdir.patch"
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use examples || cmake_comment_add_subdirectory examples
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package berkdb BDB)
+		-DICAL_BUILD_DOCS=$(usex doc)
+		-DICAL_GLIB=$(usex glib)
+		-DGOBJECT_INTROSPECTION=$(usex introspection)
+		-DSHARED_ONLY=$(usex !static-libs)
+		-DLIBICAL_BUILD_TESTING=$(usex test)
+		-DICAL_GLIB_VAPI=$(usex vala)
+	)
+	if use vala; then
+		mycmakeargs+=(
+			-DVALAC="${VALAC}"
+			-DVAPIGEN="${VAPIGEN}"
+		)
+	fi
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile docs
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(icalrecurtest|icalrecurtest-r)" # bug 660282
+	)
+
+	cmake_src_test
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
+
+	cmake_src_install
+
+	if use examples; then
+		rm examples/CMakeLists.txt || die
+		dodoc -r examples
+	fi
+}