dev-dotnet/dotnet-sdk-bin: bump to 8.0.200

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 163 insertions, 0 deletions

diff --git a/dev-dotnet/dotnet-sdk-bin/Manifest b/dev-dotnet/dotnet-sdk-bin/Manifest
index 674204985aac..4b8b5324bd47 100644
--- a/dev-dotnet/dotnet-sdk-bin/Manifest
+++ b/dev-dotnet/dotnet-sdk-bin/Manifest
@@ -22,3 +22,9 @@ DIST dotnet-sdk-8.0.101-linux-musl-arm.tar.gz 209611402 BLAKE2B d833a8bcf794e3ea
 DIST dotnet-sdk-8.0.101-linux-musl-arm64.tar.gz 209818487 BLAKE2B ac7bb3babf4008a513b57c37d8f7b8e0bdf119e51ad9e42011aba7cfe6a32e11d8d9a0b2c835d25d39ad7a74302804ecb776acf0dafe134cf276eae86ba4ddf9 SHA512 796d9fa4fda9d7d0f014820e20a8bad63052ba5e15dcb4fcb44ce33438a1aa4cd5e2ea0ad4a538b07946302b9649638762e3bfaa22a70318f0f17bc50c105193
 DIST dotnet-sdk-8.0.101-linux-musl-x64.tar.gz 214418879 BLAKE2B 981dab8fb6248749e34f7229cf0c3f3702908c6347e6cf2c266787913e79095af2acb81316a82ae55c74d4a34a4c782218c69e92ac6cf3ce6830350bc3f949c5 SHA512 95751235b774ed1050b721528495c1ba561c0bce99989a5fd6c0d0510b8b7d07a34ef186f347d16194b07d5ec4966ae8cb47aa7c1a65eebcea8a68fd90fb22e5
 DIST dotnet-sdk-8.0.101-linux-x64.tar.gz 214222713 BLAKE2B 7b886f200ec07e6625ca004c7875a3a921d2e935c0767173821502c0d37974aecf89e4bbee62c44c83f49f306107189311d94a18f4265408acbcc708e5688984 SHA512 26df0151a3a59c4403b52ba0f0df61eaa904110d897be604f19dcaa27d50860c82296733329cb4a3cf20a2c2e518e8f5d5f36dfb7931bf714a45e46b11487c9a
+DIST dotnet-sdk-8.0.200-linux-arm.tar.gz 221531494 BLAKE2B 2ee8e9115476dca7774c6eb410a537201a30d579f8c7725491a4aa7839f2bbff998dbe0e653f9a3c3ebd4b318967ba37f00a1ee58411f51950d892a2903799b1 SHA512 a7359c6b714bea6a0e56a89465866e78e241a3587b916fbd8ce4c9ea89c3bf987ab95d8b12d64308257ae0213c724ebafb34e0ff244058172b58719cef0184d5
+DIST dotnet-sdk-8.0.200-linux-arm64.tar.gz 221425754 BLAKE2B d4c967579a05429b9dea1f08a047eed34e918bcee5429e2837b4d6ae7d27fa6805e222d91b9f24b46a6eaad344fcd1cbd99f05bc895e6aba74672171ccbf6401 SHA512 ebb11b2dba2843175f55b6a78a29f6a22860eb1198e4562f206f5fd3c0cd1711bb5c8919967396ac6a0e354c43bd6d012e47fdbd85ad951c7ff0e3e87b0a0b19
+DIST dotnet-sdk-8.0.200-linux-musl-arm.tar.gz 221630199 BLAKE2B a3ffe46d7b790d9a83eb1d32d8deb9e5b6b7bde1cdf7041c028b44b128af8faa55796ac483377587e4ddbfebdabcec9ac2f07f8da891cb422207fe5c2b1527bf SHA512 2995e624ddc1dfb81b37a2865e1cef9227c473c50cf48b4e6d47032dd3763b57a2421aee1bb221c7307b18d8c2cec1a0531dda61b0ea33dd2d7b8c3b33055943
+DIST dotnet-sdk-8.0.200-linux-musl-arm64.tar.gz 221489257 BLAKE2B fd0cb9bf1007cbdc42f196674fd19e0461e9435aa4968beca051a31133b5e830dc1c9c7969f1a489efc4f18dabb2f999ac14269fb06fff1e264b22a71e407c1e SHA512 a65149b1b6eca4ebca30bf0f537e0759bc84ae6bb6ab528dcbbc357a0ebeaac21dbaab320ee97a9cb107d6b43b2f042837d669cf6c45df7f5756cfb3e7beab21
+DIST dotnet-sdk-8.0.200-linux-musl-x64.tar.gz 226287389 BLAKE2B e73229c5ce60b6d6933725ac9f911d44486cb5515baca45f8abf874d4a179eacddc6b8ea5190a552019fb1de1ff6ad0d6cb18b3e62aa1fa29cbfb8c3431f99e5 SHA512 c13d33ae2ec4ffbc8269ab89bced97fa659eaf173b0ca146f06174d51990b74bcbfb13333c9162973754ef5c328e41a52643f61fc33474c5335b6bacb9bb5fda
+DIST dotnet-sdk-8.0.200-linux-x64.tar.gz 226151582 BLAKE2B 2677de02a7725894045bddc6d1c3aa3a33cd42c41a069b76254e285f2f2e80959fbbbc4f2aa328143505da6af45fc56d387a2759074f82f0219861751a8a68d0 SHA512 58417468b72c89a66ad0bf54a0e4af13f8a3a37f2aae6e28ef762b9cdd783af0c13ad62ce185446d920b2709ec73c980d888fd73a413a8dce154ac15cb0056a3
diff --git a/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.200.ebuild b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.200.ebuild
new file mode 100644
index 000000000000..38929dc875b5
--- /dev/null
+++ b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.200.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+SDK_SLOT="$(ver_cut 1-2)"
+RUNTIME_SLOT="${SDK_SLOT}.2"
+
+DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
+HOMEPAGE="https://dotnet.microsoft.com/
+	https://github.com/dotnet/dotnet/"
+SRC_URI="
+amd64? (
+	elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-x64.tar.gz )
+	elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-x64.tar.gz )
+)
+arm? (
+	elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm.tar.gz )
+	elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm.tar.gz )
+)
+arm64? (
+	elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm64.tar.gz )
+	elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm64.tar.gz )
+)
+"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
+KEYWORDS="~amd64 ~arm ~arm64"
+
+# STRIP="llvm-strip" corrupts some executables when using the patchelf hack,
+# bug https://bugs.gentoo.org/923430
+RESTRICT="splitdebug strip"
+
+CURRENT_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
+"
+EXTRA_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-6.0.27
+	~dev-dotnet/dotnet-runtime-nugets-7.0.16
+"
+NUGETS_DEPEND="
+	${CURRENT_NUGETS_DEPEND}
+	${EXTRA_NUGETS_DEPEND}
+"
+
+RDEPEND="
+	app-crypt/mit-krb5:0/0
+	dev-libs/icu
+	dev-util/lttng-ust:0/2.12
+	sys-libs/zlib:0/1
+"
+BDEPEND="
+	dev-util/patchelf
+"
+IDEPEND="
+	app-eselect/eselect-dotnet
+"
+PDEPEND="
+	${NUGETS_DEPEND}
+"
+
+QA_PREBUILT="*"
+
+MUSL_BAD_LINKS=(
+	apphost
+	createdump
+	dotnet
+	libSystem.Globalization.Native.so
+	libSystem.IO.Compression.Native.so
+	libSystem.Native.so
+	libSystem.Net.Security.Native.so
+	libSystem.Security.Cryptography.Native.OpenSsl.so
+	libclrgc.so
+	libclrjit.so
+	libcoreclr.so
+	libcoreclrtraceptprovider.so
+	libdbgshim.so
+	libhostfxr.so
+	libhostpolicy.so
+	libmscordaccore.so
+	libmscordbi.so
+	libnethost.so
+	singlefilehost
+)
+MUSL_BAD_SONAMES=(
+	libc.musl-aarch64.so.1
+	libc.musl-armv7.so.1
+	libc.musl-x86_64.so.1
+)
+
+src_prepare() {
+	default
+
+	# Fix musl libc SONAME links, bug https://bugs.gentoo.org/894760
+	if use elibc_musl ; then
+		local musl_bad_link
+		local musl_bad_link_path
+		local musl_bad_soname
+
+		for musl_bad_link in "${MUSL_BAD_LINKS[@]}" ; do
+			while read -r musl_bad_link_path ; do
+				# Skip if file either does not end with ".so" or is not executable.
+				# Using "case" here for easier matching in case we have to add
+				# a special exception.
+				case "${musl_bad_link_path}" in
+					*.so )
+						:
+						;;
+					* )
+						if [[ ! -x "${musl_bad_link_path}" ]] ; then
+							continue
+						fi
+						;;
+				esac
+
+				einfo "Fixing musl libc link for ${musl_bad_link_path}"
+
+				for musl_bad_soname in "${MUSL_BAD_SONAMES[@]}" ; do
+					patchelf --remove-needed "${musl_bad_soname}" "${musl_bad_link_path}" || die
+				done
+
+				patchelf --add-needed libc.so "${musl_bad_link_path}" || die
+			done < <(find . -type f -name "${musl_bad_link}")
+		done
+	fi
+
+	# Remove static libraries, bug https://bugs.gentoo.org/825774
+	find ./packs -type f -name "libnethost.a" -delete || die
+}
+
+src_install() {
+	local dest="opt/${PN}-${SDK_SLOT}"
+	dodir "${dest%/*}"
+
+	# Create a magic workloads file, bug #841896
+	local featureband="$(( $(ver_cut 3) / 100 * 100 ))"       # e.g. 404 -> 400
+	local workloads="metadata/workloads/${SDK_SLOT}.${featureband}"
+
+	mkdir -p "${S}/${workloads}" || die
+	touch "${S}/${workloads}/userlocal" || die
+
+	mv "${S}" "${ED}/${dest}" || die
+	mkdir "${S}" || die
+
+	fperms 0755 "/${dest}"
+	dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SDK_SLOT}"
+}
+
+pkg_postinst() {
+	eselect dotnet update ifunset
+}
+
+pkg_postrm() {
+	eselect dotnet update ifunset
+}