dev-db/pgadmin4: Bump to 2.1

Package-Manager: Portage-2.3.13, Repoman-2.3.3

2 files changed, 123 insertions, 0 deletions

diff --git a/dev-db/pgadmin4/Manifest b/dev-db/pgadmin4/Manifest
index 793f3fffab4a..819b5bbda075 100644
--- a/dev-db/pgadmin4/Manifest
+++ b/dev-db/pgadmin4/Manifest
@@ -1 +1,2 @@
 DIST pgadmin4-2.0.tar.gz 24988176 BLAKE2B 96e942d5001b1d590fb1b642933c665a13bca5429d3a3e74eefe4a8090c76515cc08b656ebfea3a170b4fa6077d7086fbffdd5fddfcb517be08fd4ecc20052ab SHA512 463e95a341dec74ac0a08a647af1cbe83b514b0595b8469ab9c7b5335e24604e082b906d530aa735fef7b08c58d8a8a6df3edf5dc65402f6521165f1cbb72f67
+DIST pgadmin4-2.1.tar.gz 27842212 BLAKE2B 26c12dff8e2e5e37dd2911f6eb582a0f706d73490c8d93e83b07b7537fc201547d095d4f34181d2502bbc29b2741614adabf876b7e6ea3ef5f555eab94caa240 SHA512 02bc122ae53db595a1fd395e634fc4d0891f024a2e5e341c81b306a8c1d07bc18e5673cda440c7ba56754be4902ae4441010db0140132352e12b8986c8c0f47c
diff --git a/dev-db/pgadmin4/pgadmin4-2.1.ebuild b/dev-db/pgadmin4/pgadmin4-2.1.ebuild
new file mode 100644
index 000000000000..6f3816804830
--- /dev/null
+++ b/dev-db/pgadmin4/pgadmin4-2.1.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5} )
+PYTHON_REQ_USE="sqlite"
+
+inherit python-single-r1 qmake-utils
+
+DESCRIPTION="GUI administration and development platform for PostgreSQL"
+HOMEPAGE="http://www.pgadmin.org/"
+SRC_URI="mirror://postgresql/pgadmin/${PN}/v${PV}/source/${P}.tar.gz"
+
+LICENSE="POSTGRESQL"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="doc"
+
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-qt/qtwidgets:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwebengine:5[widgets]
+"
+
+DEPEND="${COMMON_DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=app-text/htmlmin-0.1.10[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.3[${PYTHON_USEDEP}]
+	>=dev-python/click-6.6[${PYTHON_USEDEP}]
+	>=dev-python/extras-0.0.3[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.11.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-babel-0.11.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-gravatar-0.4.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-htmlmin-1.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-login-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-mail-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-migrate-2.0.3[${PYTHON_USEDEP}]
+	>=dev-python/flask-paranoid-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-principal-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-security-1.7.5[${PYTHON_USEDEP}]
+	>=dev-python/flask-sqlalchemy-2.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-wtf-0.12[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-0.9999999[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.24[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.7.3[${PYTHON_USEDEP}]
+	>=dev-python/linecache2-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-0.23[${PYTHON_USEDEP}]
+	>=dev-python/mimeparse-1.5.1[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.6.2[${PYTHON_USEDEP}]
+	>=dev-python/pbr-1.9.1[${PYTHON_USEDEP}]
+	>=dev-python/psycopg-2.7.3.2[${PYTHON_USEDEP}]
+	>=dev-python/pycrypto-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.11.13[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/python-sqlparse-0.1.19[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2014.10[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.6.5[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/speaklater-1.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.0.14[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/wtforms-2.0.2[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}"/${P}/runtime
+
+src_prepare() {
+	cd "${WORKDIR}"/${P} || die
+	default
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_compile() {
+	default
+	if use doc; then
+		cd "${WORKDIR}"/${P} || die
+		emake docs
+	fi
+}
+
+src_install() {
+	dobin pgAdmin4
+
+	cd "${WORKDIR}"/${P} || die
+
+	local APP_DIR=/usr/share/${PN}/web
+	insinto "${APP_DIR}"
+	doins -r web/*
+	cat > "${D}${APP_DIR}"/config_local.py <<-EOF
+		SERVER_MODE = False
+		UPGRADE_CHECK_ENABLED = False
+	EOF
+	python_optimize "${D}${APP_DIR}"
+
+	local CONFIG_DIR="/etc/xdg/pgadmin"
+	dodir "${CONFIG_DIR}"
+	cat > "${D}${CONFIG_DIR}"/pgadmin4.conf <<-EOF
+		[General]
+		ApplicationPath=${APP_DIR}
+		PythonPath=$(python_get_sitedir)
+	EOF
+
+	if use doc; then
+		rm -r docs/en_US/_build/html/_sources || die
+		insinto /usr/share/${PN}/docs/en_US/_build
+		doins -r docs/en_US/_build/html
+	fi
+}