app-text/qpdfview: version bump; EAPI=6; drop USE=qt4 to respect Qt team policy

Gentoo-Bug: 565788

Package-Manager: portage-2.2.28

2 files changed, 98 insertions, 0 deletions

diff --git a/app-text/qpdfview/Manifest b/app-text/qpdfview/Manifest
index c1a18069a3cf..333b1e9fb52d 100644
--- a/app-text/qpdfview/Manifest
+++ b/app-text/qpdfview/Manifest
@@ -1,2 +1,3 @@
 DIST qpdfview-0.4.13.tar.gz 563548 SHA256 8ff563055fb4df476afed08ead465e6204c16fc419a483ebf3dbe89779f28e41 SHA512 0246a2954ca01a1b3df69473ee53c7674ee891c460a26aebbf8acf2505692ec40eb712388893eddf6954180ddadb7965f173b9e55a3574f2cc8c0820d78be952 WHIRLPOOL 702ba4b5f1c597dfb4483775d9b089ff263594d99f7c9866c81ffb1a7755615b960c90a3b6c7cb8ea4b0d078c7d80b645612b5ce2eb618b2fedb785a6c67a725
 DIST qpdfview-0.4.15.tar.gz 611036 SHA256 a2dca83bc12c1241fc0603f8fb029a5d5011c68f9266d4a3a804fb75bf00f271 SHA512 dd87bcb62af75e3d96197f2ff6a76dde5c4a418dd6989050b9a606370b4a7f437a8a94fdef5f947e519b2880cb374af5f406ff4201bcd52da7a98949e63b02e4 WHIRLPOOL b78b76fa29f7775c3120bfd4487fb0dbcad82da923d5f02ba160912a9ecc1cc5831353b999c2ec36d9dbc7e464b650e4c1f753eb0f5ebe7d3014c0fb568dcf82
+DIST qpdfview-0.4.16.tar.gz 636095 SHA256 fad416e8fefc3057fa1b8d12d964c7eccd16dffe0307a0d6e9d55a543294da7f SHA512 d3ac05fc51d48533e44e58cd19e5d222a8bfbc9da4df02ece6a405d2fdd3346eb4614816ae91e89facf28e107b920ff3ce7b2ccc8c9b7832ae2595ef70d65584 WHIRLPOOL 47bc82937562fdcbdf17f567bb0fa6e8eebd2e657320c129e9fd4f592c27eab855e7d2d69a22b45666509ace93b12528811b0671cb9483607448152bb676f11e
diff --git a/app-text/qpdfview/qpdfview-0.4.16.ebuild b/app-text/qpdfview/qpdfview-0.4.16.ebuild
new file mode 100644
index 000000000000..293de8c26360
--- /dev/null
+++ b/app-text/qpdfview/qpdfview-0.4.16.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PLOCALES="ast az be bg bs ca cs da de el en_GB eo es eu fi fr gl he hr hu id it kk ko ky lt ms my pl pt pt_BR ro ru sk sv th tr ug uk vi zh_CN"
+
+inherit l10n qmake-utils
+
+DESCRIPTION="A tabbed document viewer"
+HOMEPAGE="https://launchpad.net/qpdfview"
+SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="cups +dbus djvu fitz +pdf postscript qt5 +sqlite +svg synctex"
+
+REQUIRED_USE="?? ( fitz pdf )"
+
+RDEPEND="
+	cups? ( net-print/cups )
+	djvu? ( app-text/djvu )
+	fitz? ( >=app-text/mupdf-1.7:= )
+	postscript? ( app-text/libspectre )
+	!qt5? ( dev-qt/qtcore:4[iconv]
+		dev-qt/qtgui:4
+		sys-apps/file
+		dbus? ( dev-qt/qtdbus:4 )
+		pdf? ( >=app-text/poppler-0.35[qt4] )
+		sqlite? ( dev-qt/qtsql:4[sqlite] )
+		svg? ( dev-qt/qtsvg:4 ) )
+	qt5? ( dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+		dbus? ( dev-qt/qtdbus:5 )
+		pdf? ( >=app-text/poppler-0.35[qt5]
+			dev-qt/qtxml:5 )
+		sqlite? ( dev-qt/qtsql:5[sqlite] )
+		svg? ( dev-qt/qtsvg:5 ) )
+	!svg? ( virtual/freedesktop-icon-theme )
+	synctex? ( app-text/texlive-core )"
+DEPEND="${RDEPEND}
+	qt5? ( dev-qt/linguist-tools:5 )
+	virtual/pkgconfig"
+
+DOCS=( CHANGES CONTRIBUTORS README TODO )
+
+src_prepare() {
+	local mylrelease="$(qt4_get_bindir)"/lrelease
+	use qt5 && mylrelease="$(qt5_get_bindir)"/lrelease
+
+	prepare_locale() {
+		"${mylrelease}" "translations/${PN}_${1}.ts" || die "preparing ${1} locale failed"
+	}
+
+	rm_help() {
+		rm -f "help/help_${1}.html" || die "removing ${1} help file failed"
+	}
+
+	l10n_find_plocales_changes translations ${PN}_ .ts
+	l10n_for_each_locale_do prepare_locale
+	l10n_for_each_disabled_locale_do rm_help
+
+	# adapt for prefix
+	sed -i -e "s:/usr:${EPREFIX}/usr:g" qpdfview.pri || die
+
+	default
+}
+
+src_configure() {
+	local myconfig=() i=
+	for i in cups dbus djvu pdf svg synctex; do
+		use ${i} || myconfig+=(without_${i})
+	done
+	use fitz && myconfig+=(with_fitz)
+	use postscript || myconfig+=(without_ps)
+	use sqlite || myconfig+=(without_sql)
+
+	local myqmakeargs=(
+		qpdfview.pro
+		CONFIG+="${myconfig[@]}"
+		PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}"
+	)
+	if use qt5; then
+		eqmake5 "${myqmakeargs[@]}"
+	else
+		eqmake4 "${myqmakeargs[@]}"
+	fi
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}