app-text/paper-clip: bump to 4.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/app-text/paper-clip/Manifest b/app-text/paper-clip/Manifest
index fae5a151391d..db7265d140b2 100644
--- a/app-text/paper-clip/Manifest
+++ b/app-text/paper-clip/Manifest
@@ -1 +1,2 @@
 DIST paper-clip-3.6.tar.gz 171190 BLAKE2B a31673c9c3a1f889a63561a244d966195dac2738eb4070dfd01807c7406c7f8acb0277509c6924de37068aa904c3f1ee4f6de3882bf734470b67dd77b34afcf3 SHA512 4ebfa6789d31f85dc6b38119f7fb1f88ca06a32872ab1341d4a4fcd898eb3c672673a630d56f373294c053bdcee7573206a5fe89da45b76366f65e9bb441451a
+DIST paper-clip-4.0.tar.gz 179221 BLAKE2B 37f1e8fe73ed333c1ffaf72ce587581a54f464b326dfbb060e241aec3ee6219ba8e988cf49642a6429213b731aad218fbf174845553987f9c269d8640d71da28 SHA512 7ebc657e2e3d42eb70b63eee254cb68a989211445381d397394b28c2939f292e4b2329ed9747a516aca6df7e261894b347dda8e718c032624e2a8aed96bd4bc3
diff --git a/app-text/paper-clip/paper-clip-4.0.ebuild b/app-text/paper-clip/paper-clip-4.0.ebuild
new file mode 100644
index 000000000000..8a822daeac38
--- /dev/null
+++ b/app-text/paper-clip/paper-clip-4.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+APP_PN="Paper-Clip"
+
+inherit gnome2-utils meson vala xdg
+
+DESCRIPTION="Edit the title, author, keywords and more details of PDF documents"
+HOMEPAGE="https://github.com/Diego-Ivan/Paper-Clip/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/Diego-Ivan/${APP_PN}.git"
+else
+	SRC_URI="https://github.com/Diego-Ivan/${APP_PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${APP_PN}-${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+RESTRICT="test"                      # Only validations, the appdata one fails.
+
+RDEPEND="
+	>=gui-libs/gtk-4.12.5:4
+	>=gui-libs/libadwaita-1.4.2:1[introspection,vala]
+	app-text/poppler:=[cairo,introspection]
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	dev-libs/libportal:=[gtk,introspection,vala]
+	media-libs/exempi
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+"
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_install() {
+	meson_src_install
+	einstalldocs
+
+	# Symlink "pdf-metadata-editor" (old name?) to "${PN}".
+	dosym -r /usr/bin/pdf-metadata-editor "/usr/bin/${PN}"
+
+	mv "${ED}/usr/share/appdata" "${ED}/usr/share/metainfo" || die
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}