app-pda/libplist: version bumps, fix multi-python builds

Reworked the ebuild so that it will properly build for multiple python
implementations.  Committed 1.11-r2 for immediate stablereq, and bumped to latest
upstream 1.12

Package-Manager: portage-2.2.24

3 files changed, 159 insertions, 0 deletions

diff --git a/app-pda/libplist/Manifest b/app-pda/libplist/Manifest
index ca10a4fc8e5c..020ea780f113 100644
--- a/app-pda/libplist/Manifest
+++ b/app-pda/libplist/Manifest
@@ -1 +1,2 @@
 DIST libplist-1.11.tar.bz2 355365 SHA256 28e1518eeea054f4eec9a1c93d9575d56193b290c53c1b753773a5e0add95235 SHA512 1c415670877c7091ded541dc36a6bc91132f714a0d3590090ead40ed972e0e076285441d3d219827cc425bc41fcbc101825e937620b7b4f2c1afe4bef8487fa2 WHIRLPOOL a2c74d3454b80696ab45922fe410833912554588d9ed5c177cbed1865bd98099b29a20ab6cf14a0b7c98de59d082fd15392915a94f33d27b16109300a0de2e4c
+DIST libplist-1.12.tar.bz2 384321 SHA256 0effdedcb3de128c4930d8c03a3854c74c426c16728b8ab5f0a5b6bdc0b644be SHA512 8af40d8f457ca9a8a9061e9429698c696200714cc05dcbe981e900106c52cd5222edb9dd8d8976bccd0c8997508ed14fb2e10f0ed29383f2ad4f7c5eb7eec0b3 WHIRLPOOL 7d3c4f7822683018b5b0e794d509b9cf5a703605ed772df849ad9ebba6e8191f2eb629444c07d2dcb265520d24c94f13287f200fec34779c9e6fe029536183a7
diff --git a/app-pda/libplist/libplist-1.11-r2.ebuild b/app-pda/libplist/libplist-1.11-r2.ebuild
new file mode 100644
index 000000000000..2f5331b864b2
--- /dev/null
+++ b/app-pda/libplist/libplist-1.11-r2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+inherit eutils python-r1
+
+DESCRIPTION="Support library to deal with Apple Property Lists (Binary & XML)"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/2" # based on SONAME of libplist.so
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+IUSE="python static-libs"
+
+RDEPEND=">=dev-libs/libxml2-2.7.8
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS NEWS README )
+
+RESTRICT="test" # TODO: src_test() was dropped from 1.10 (cmake) -> 1.11 (autotools)
+
+BUILD_DIR="${S}_build"
+
+src_configure() {
+	local ECONF_SOURCE=${S}
+	local myeconfargs=( $(use_enable static-libs static) )
+
+	do_configure() {
+		mkdir -p "${BUILD_DIR}" || die
+		pushd "${BUILD_DIR}" >/dev/null || die
+		econf "${myeconfargs[@]}" "${@}"
+		popd >/dev/null || die
+	}
+
+	do_configure --without-cython
+	use python && python_foreach_impl do_configure
+}
+
+src_compile() {
+	python_compile() {
+		emake -C "${BUILD_DIR}"/cython -j1 \
+			VPATH="${S}/cython:${native_builddir}/cython" \
+			plist_la_LIBADD="${native_builddir}/src/libplist.la"
+	}
+
+	local native_builddir=${BUILD_DIR}
+	pushd "${BUILD_DIR}" >/dev/null || die
+	emake -j1
+	use python && python_foreach_impl python_compile
+	popd >/dev/null || die
+}
+
+src_install() {
+	python_install() {
+		emake -C "${BUILD_DIR}/cython" -j1 \
+			VPATH="${S}/cython:${native_builddir}/cython" \
+			DESTDIR="${D}" install
+	}
+
+	local native_builddir=${BUILD_DIR}
+	pushd "${BUILD_DIR}" >/dev/null || die
+	emake -j1 DESTDIR="${D}" install
+	use python && python_foreach_impl python_install
+	popd >/dev/null || die
+
+	if use python ; then
+		insinto /usr/include/plist/cython
+		doins cython/plist.pxd
+	fi
+	prune_libtool_files --all
+}
diff --git a/app-pda/libplist/libplist-1.12.ebuild b/app-pda/libplist/libplist-1.12.ebuild
new file mode 100644
index 000000000000..f674ed03a676
--- /dev/null
+++ b/app-pda/libplist/libplist-1.12.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+inherit eutils python-r1
+
+DESCRIPTION="Support library to deal with Apple Property Lists (Binary & XML)"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/3" # based on SONAME of libplist.so
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+IUSE="python static-libs"
+
+RDEPEND=">=dev-libs/libxml2-2.7.8
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS NEWS README )
+
+RESTRICT="test" # TODO: src_test() was dropped from 1.10 (cmake) -> 1.11 (autotools)
+
+BUILD_DIR="${S}_build"
+
+src_configure() {
+	local ECONF_SOURCE=${S}
+	local myeconfargs=( $(use_enable static-libs static) )
+
+	do_configure() {
+		mkdir -p "${BUILD_DIR}" || die
+		pushd "${BUILD_DIR}" >/dev/null || die
+		econf "${myeconfargs[@]}" "${@}"
+		popd >/dev/null || die
+	}
+
+	do_configure --without-cython
+	use python && python_foreach_impl do_configure
+}
+
+src_compile() {
+	python_compile() {
+		emake -C "${BUILD_DIR}"/cython -j1 \
+			VPATH="${S}/cython:${native_builddir}/cython" \
+			plist_la_LIBADD="${native_builddir}/src/libplist.la"
+	}
+
+	local native_builddir=${BUILD_DIR}
+	pushd "${BUILD_DIR}" >/dev/null || die
+	emake -j1
+	use python && python_foreach_impl python_compile
+	popd >/dev/null || die
+}
+
+src_install() {
+	python_install() {
+		emake -C "${BUILD_DIR}/cython" -j1 \
+			VPATH="${S}/cython:${native_builddir}/cython" \
+			DESTDIR="${D}" install
+	}
+
+	local native_builddir=${BUILD_DIR}
+	pushd "${BUILD_DIR}" >/dev/null || die
+	emake -j1 DESTDIR="${D}" install
+	use python && python_foreach_impl python_install
+	popd >/dev/null || die
+
+	if use python ; then
+		insinto /usr/include/plist/cython
+		doins cython/plist.pxd
+	fi
+	prune_libtool_files --all
+}