app-eselect/eselect-repository: Bump to v11, with py3.10 and tests!

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/app-eselect/eselect-repository/eselect-repository-11.ebuild b/app-eselect/eselect-repository/eselect-repository-11.ebuild
new file mode 100644
index 000000000000..8a6bf3e77577
--- /dev/null
+++ b/app-eselect/eselect-repository/eselect-repository-11.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit python-single-r1
+
+DESCRIPTION="Manage repos.conf via eselect"
+HOMEPAGE="https://github.com/mgorny/eselect-repository"
+SRC_URI="https://github.com/mgorny/eselect-repository/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="${PYTHON_DEPS}
+	app-admin/eselect
+	$(python_gen_cond_dep '
+		dev-python/lxml[${PYTHON_USEDEP}]
+	')
+	net-misc/wget"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)"
+
+src_compile() {
+	MAKEARGS=(
+		PREFIX="${EPREFIX}/usr"
+		SYSCONFDIR="${EPREFIX}/etc"
+		SHAREDSTATEDIR="${EPREFIX}/var"
+		ESELECTDIR="${EPREFIX}/usr/share/eselect/modules"
+	)
+
+	emake "${MAKEARGS[@]}"
+	python_fix_shebang eselect-repo-helper
+}
+
+src_test() {
+	epytest
+}
+
+src_install() {
+	emake "${MAKEARGS[@]}" DESTDIR="${D}" install
+	einstalldocs
+}