app-backup/burp: Rev-bump to enforce upgrade of broken installs

See commit e84839054932a23e20fb788532f731cff6f82577.

Package-Manager: portage-2.2.26

3 files changed, 100 insertions, 0 deletions

diff --git a/app-backup/burp/burp-1.3.48-r1.ebuild b/app-backup/burp/burp-1.3.48-r1.ebuild
new file mode 100644
index 000000000000..a1f8e3fe712e
--- /dev/null
+++ b/app-backup/burp/burp-1.3.48-r1.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils user
+
+DESCRIPTION="Network backup and restore client and server for Unix and Windows"
+HOMEPAGE="http://burp.grke.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	http://burp.grke.org/downloads/${P}/${P}.tar.bz2"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="acl afs ipv6 nls tcpd xattr"
+
+DEPEND="
+	dev-libs/openssl:0
+	dev-libs/uthash
+	sys-libs/libcap
+	<net-libs/librsync-2.0
+	sys-libs/ncurses:0=
+	sys-libs/zlib
+	acl? ( sys-apps/acl )
+	afs? ( net-fs/openafs )
+	nls? ( sys-devel/gettext )
+	tcpd? ( sys-apps/tcp-wrappers )
+	xattr? ( sys-apps/attr )
+	"
+RDEPEND="${DEPEND}
+	virtual/logger
+	"
+
+DOCS=( CONTRIBUTORS DONATIONS UPGRADING )
+PATCHES=(
+	"${FILESDIR}/${PV}-non-zero-or-build-failure.patch"
+	"${FILESDIR}/${PV}-bedup-conf-path.patch"
+	"${FILESDIR}/${PV}-tinfo.patch"
+	"${FILESDIR}/${PV}-0001-Set-default_md-sha256-in-CA.cnf.patch"
+	)
+S="${WORKDIR}/burp"
+
+pkg_setup() {
+	enewgroup "${PN}"
+	enewuser "${PN}" -1 "" "" "${PN}"
+}
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+	# see bug #426262
+	mv configure.in configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--sbindir=/usr/sbin
+		--sysconfdir=/etc/burp
+		--enable-largefile
+		$(use_enable acl)
+		$(use_enable afs)
+		$(use_enable ipv6)
+		$(use_enable nls)
+		$(use_enable xattr)
+		$(use_with tcpd tcp-wrappers)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	fowners root:burp /etc/burp /var/spool/burp
+	fperms 0775 /etc/burp /var/spool/burp
+	fowners root:burp /etc/burp/clientconfdir
+	fperms 0750 /etc/burp/clientconfdir
+	fowners root:burp /etc/burp/burp-server.conf
+	fperms 0640 /etc/burp/burp-server.conf
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	dodoc docs/*
+
+	sed -e 's|^# user=graham|user = burp|' \
+		-e 's|^# group=nogroup|group = burp|' \
+		-e 's|^pidfile = .*|lockfile = /run/lock/burp/server.lock|' \
+		-i "${D}"/etc/burp/burp-server.conf || die
+}
+
+pkg_postinst() {
+	if [[ ! -e /etc/burp/CA/index.txt ]]; then
+		elog "At first run burp server will generate DH parameters and SSL"
+		elog "certificates.  You should adjust configuration before."
+		elog "Server configuration is located at"
+		elog ""
+		elog "  /etc/burp/burp-server.conf"
+		elog ""
+	fi
+}
diff --git a/app-backup/burp/burp-1.3.8.ebuild b/app-backup/burp/burp-1.3.8-r1.ebuild
index 3c136e557d41..3c136e557d41 100644
--- a/app-backup/burp/burp-1.3.8.ebuild
+++ b/app-backup/burp/burp-1.3.8-r1.ebuild
diff --git a/app-backup/burp/burp-1.4.40.ebuild b/app-backup/burp/burp-1.4.40-r1.ebuild
index edfa6afd52b2..edfa6afd52b2 100644
--- a/app-backup/burp/burp-1.4.40.ebuild
+++ b/app-backup/burp/burp-1.4.40-r1.ebuild