media-sound/jack-rack: Drop USE gnome

Closes: https://bugs.gentoo.org/644328
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 65 insertions, 0 deletions

diff --git a/media-sound/jack-rack/jack-rack-1.4.8_rc1-r1.ebuild b/media-sound/jack-rack/jack-rack-1.4.8_rc1-r1.ebuild
new file mode 100644
index 000000000000..f92eced8b109
--- /dev/null
+++ b/media-sound/jack-rack/jack-rack-1.4.8_rc1-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_P=${PN}_${PV/_/\~}
+DEB_URI="mirror://debian/pool/main/j/${PN}"
+
+DESCRIPTION="JACK Rack is an effects rack for the JACK low latency audio API"
+HOMEPAGE="http://jack-rack.sourceforge.net/"
+SRC_URI="${DEB_URI}/${MY_P}.orig.tar.gz ${DEB_URI}/${MY_P}-1.debian.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="alsa lash +xml"
+
+RDEPEND="
+	media-libs/ladspa-sdk
+	virtual/jack
+	virtual/libintl
+	x11-libs/gtk+:2
+	alsa? ( media-libs/alsa-lib:= )
+	lash? ( media-sound/lash:= )
+	xml? (
+		dev-libs/libxml2:=
+		media-libs/liblrdf:=
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}-f9fb65d"
+
+PATCHES=(
+	"${WORKDIR}"/debian/patches/01-desktop_file.patch
+	"${WORKDIR}"/debian/patches/02-gcc45_binutils_gold.patch
+	"${WORKDIR}"/debian/patches/03-remove_midi_when_replacing_plugin.patch
+	"${FILESDIR}"/${PN}-1.4.6-noalsa.patch
+	"${FILESDIR}"/${PN}-1.4.7-disable_deprecated.patch
+	"${FILESDIR}"/${P}-noxml.patch
+	"${FILESDIR}"/${P}-underlinking.patch
+	"${FILESDIR}"/${P}-QA-fix-desktop-file.patch
+)
+
+src_prepare() {
+	default
+	eautopoint
+	eautoreconf
+}
+
+src_configure() {
+	# Use lrdf.pc to get -I/usr/include/raptor2 (lrdf.h -> raptor.h)
+	use xml && append-cppflags $($(tc-getPKG_CONFIG) --cflags lrdf)
+
+	econf \
+		$(use_enable alsa aseq) \
+		--disable-gnome \
+		$(use_enable lash) \
+		$(use_enable xml) \
+		$(use_enable xml lrdf)
+}