dev-python/m2crypto: add 0.40.0, 0.40.1

Signed-off-by: orbea <orbea@riseup.net>

3 files changed, 160 insertions, 0 deletions

diff --git a/dev-python/m2crypto/Manifest b/dev-python/m2crypto/Manifest
index 7634d00..0274b51 100644
--- a/dev-python/m2crypto/Manifest
+++ b/dev-python/m2crypto/Manifest
@@ -1 +1,3 @@
 DIST M2Crypto-0.39.0.tar.gz 1248372 BLAKE2B f89793b847fae3c51a0ea79c3ba861d26b53fa12b2c8d68c3b3476bb2c944b586e875bea0c4693c213e024024096a06de0734631e546c4284d65fc5494784476 SHA512 5d8210c6204fd71f06d238c5b1fe08dd38d6b8e92db7b1e433a9e4e2fe9af46d6d55df7550716a7d05328fb3c9eed427f015b7d5a1fe33a073f0af15a82ab050
+DIST M2Crypto-0.40.0.tar.gz 1265903 BLAKE2B 3e322b46d23bad1e3e4024006f5053a4a13ba974137bc17a1493716c76d02704e37b79677604557abe3478128159ab8641238610ae364c421452e40fe8f5e8ba SHA512 3e04cd8fad1149707c670a10e95d453c0f0f725ab9416f119a3c7c301a6aab42efe1ee68bd9a96d7e014f5596c82c43d20b95219c260ded26d50079bcf3d2b89
+DIST M2Crypto-0.40.1.tar.gz 1266138 BLAKE2B a44de6b66695e0fbbba671682a7773ddbbd15225d27329d357e0005e395a70c6b006401ec30fb6938c9c4683377519844ea646df7c176181977139f6381c6907 SHA512 ca914de14621af4aa9b7f11664702557e596438cc76869478a2a75eb37ca14243e7064db7e32985834260ffa9136836884e60916d542a685ac3f1481b9320b69
diff --git a/dev-python/m2crypto/m2crypto-0.40.0.ebuild b/dev-python/m2crypto/m2crypto-0.40.0.ebuild
new file mode 100644
index 0000000..fea5589
--- /dev/null
+++ b/dev-python/m2crypto/m2crypto-0.40.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 2018-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{10..12} )
+PYPI_NO_NORMALIZE=1
+PYPI_PN="M2Crypto"
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="A Python crypto and SSL toolkit"
+HOMEPAGE="
+	https://gitlab.com/m2crypto/m2crypto/
+	https://pypi.org/project/M2Crypto/
+"
+
+# openssl via src/SWIG/_lib11_compat.i
+LICENSE="MIT openssl"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test abi_mips_n32 abi_mips_n64 abi_mips_o32"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=dev-lang/swig-2.0.9
+"
+RDEPEND="
+	dev-libs/openssl:=
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_tests setup.py
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-libressl-0.38.0.patch
+)
+
+swig_define() {
+	local x
+	for x; do
+		if tc-cpp-is-true "defined(${x})"; then
+			SWIG_FEATURES+=" -D${x}"
+		fi
+	done
+}
+
+src_prepare() {
+	# relies on very exact clock behavior which apparently fails
+	# with inconvenient CONFIG_HZ*
+	sed -e 's:test_server_simple_timeouts:_&:' \
+		-i tests/test_ssl.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	# setup.py looks at platform.machine() to determine swig options.
+	# For exotic ABIs, we need to give swig a hint.
+	local -x SWIG_FEATURES=
+
+	# https://bugs.gentoo.org/617946
+	swig_define __ILP32__
+
+	# https://bugs.gentoo.org/674112
+	swig_define __ARM_PCS_VFP
+
+	# Avoid similar errors to bug #688668 for MIPS
+	if use abi_mips_n32; then
+	    swig_define _MIPS_SIM = _ABIN32
+	elif use abi_mips_n64; then
+	    swig_define _MIPS_SIM = _ABI64
+	elif use abi_mips_o32; then
+	    swig_define _MIPS_SIM = _ABIO32
+	fi
+
+	distutils-r1_python_compile --openssl="${ESYSROOT}"/usr
+}
diff --git a/dev-python/m2crypto/m2crypto-0.40.1.ebuild b/dev-python/m2crypto/m2crypto-0.40.1.ebuild
new file mode 100644
index 0000000..119c946
--- /dev/null
+++ b/dev-python/m2crypto/m2crypto-0.40.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 2018-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{10..12} )
+PYPI_NO_NORMALIZE=1
+PYPI_PN="M2Crypto"
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="A Python crypto and SSL toolkit"
+HOMEPAGE="
+	https://gitlab.com/m2crypto/m2crypto/
+	https://pypi.org/project/M2Crypto/
+"
+
+# openssl via src/SWIG/_lib11_compat.i
+LICENSE="MIT openssl"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test abi_mips_n32 abi_mips_n64 abi_mips_o32"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=dev-lang/swig-2.0.9
+"
+RDEPEND="
+	dev-libs/openssl:=
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-libressl-0.38.0.patch
+)
+
+distutils_enable_tests setup.py
+
+swig_define() {
+	local x
+	for x; do
+		if tc-cpp-is-true "defined(${x})"; then
+			SWIG_FEATURES+=" -D${x}"
+		fi
+	done
+}
+
+src_prepare() {
+	# relies on very exact clock behavior which apparently fails
+	# with inconvenient CONFIG_HZ*
+	sed -e 's:test_server_simple_timeouts:_&:' \
+		-i tests/test_ssl.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	# setup.py looks at platform.machine() to determine swig options.
+	# For exotic ABIs, we need to give swig a hint.
+	local -x SWIG_FEATURES=
+
+	# https://bugs.gentoo.org/617946
+	swig_define __ILP32__
+
+	# https://bugs.gentoo.org/674112
+	swig_define __ARM_PCS_VFP
+
+	# Avoid similar errors to bug #688668 for MIPS
+	if use abi_mips_n32; then
+	    swig_define _MIPS_SIM = _ABIN32
+	elif use abi_mips_n64; then
+	    swig_define _MIPS_SIM = _ABI64
+	elif use abi_mips_o32; then
+	    swig_define _MIPS_SIM = _ABIO32
+	fi
+
+	distutils-r1_python_compile --openssl="${ESYSROOT}"/usr
+}