blob: 0523fa2c630cd3100c9b68e21f426e958e9e6ce5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..11} )
PYTHON_REQ_USE="ssl"
DISTUTILS_USE_PEP517=poetry
inherit databases distutils-r1 optfeature
DESCRIPTION="A fast asyncio MySQL driver"
HOMEPAGE="
https://pypi.org/project/asyncmy/
https://github.com/long2ice/asyncmy
"
SRC_URI="https://github.com/long2ice/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
TEST_S="${S}_test"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
BDEPEND="
dev-python/cython[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
$(emysql --get-depend)
)
"
distutils_enable_tests pytest
src_unpack() {
default
cp -a "${S}" "${TEST_S}" || die
rm -r "${TEST_S}"/asyncmy || die
}
src_test() {
emysql --start
local sockfile=$(emysql --get-sockfile)
local myargs=(
--user=root
--socket="${sockfile}"
--silent
--execute="ALTER USER 'root'@'localhost' IDENTIFIED BY '123456';"
)
ebegin "Changing database password"
mysql "${myargs[@]}"
eend $? || emysql --die "Changing database password failed"
distutils-r1_src_test
emysql --stop
}
python_test() {
cd "${T}" || die
epytest "${TEST_S}"
}
src_install() {
distutils-r1_src_install
find "${ED}"/usr/lib -name '*.md' -delete || die
}
pkg_postinst() {
optfeature "sha256_password and caching_sha2_password auth methods" dev-python/cryprography
}
|
GitWeb
