app-text/komikku: add 1.5.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

2 files changed, 92 insertions, 0 deletions

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 467e00a0e..26a43375f 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST Komikku-1.4.1.tar.bz2 4306317 BLAKE2B 2e483dd7c1c932162a7fb855b7edf6d3ccbd8866e532b6994e719db65c1cd18793cb05110dde166b7de4df979dc82ec905e8e54e72e67146894a9eaaf86af15f SHA512 3f712220f948d03f2a45b50cb701fa7ddf78410f42a5dd62af300cb717b1c5514da3830ac3688294e707800da061feede4200b92c2bf0191a0e61693b9dcca0a
+DIST Komikku-1.5.0.tar.bz2 4306815 BLAKE2B 4729908bc5f117adb893ca8705c126fcf17afbd3ac7356ef1c277105f8430b09a41bf5b621fc40017527e2028de7c8126e3133e6efa0bc64aec6ca2f48d0523a SHA512 5b9aa5c4351ed52d13495ee230453de52873355acbe90748a72184af02f8c38a76e6c025df285d84846333b5943ea696dd4515b371e30a02a5dba8e92099ed29
diff --git a/app-text/komikku/komikku-1.5.0.ebuild b/app-text/komikku/komikku-1.5.0.ebuild
new file mode 100644
index 000000000..69fa12dd4
--- /dev/null
+++ b/app-text/komikku/komikku-1.5.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils virtualx xdg
+
+MY_PN="${PN^}"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="An online/offline manga reader for GNOME"
+HOMEPAGE="https://gitlab.com/valos/Komikku"
+SRC_URI="https://gitlab.com/valos/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection[${PYTHON_SINGLE_USEDEP}]
+	>=gui-libs/gtk-4.8.2:4
+	>=gui-libs/libadwaita-1.2.0[introspection]
+	net-libs/webkit-gtk:5[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/cffi[${PYTHON_USEDEP}]
+		dev-python/cloudscraper[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# fix broken shebang
+	sed "s|py_installation.path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	virtx epytest
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}