dev-embedded/pk2cmd/pk2cmd-1.20.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/pk2cmd/pk2cmd-1.20.ebuild,v 1.5 2015/01/05 15:24:14 mrueg Exp $

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="An application for working with the Microchip PicKit2 PIC programmer"
HOMEPAGE="http://www.microchip.com/pickit2"
SRC_URI="http://ww1.microchip.com/downloads/en/DeviceDoc/${PN}v${PV}LinuxMacSource.tar.gz"

LICENSE="MicroChip-PK2"
SLOT="0"
KEYWORDS="~amd64 ppc ppc64 ~x86"
IUSE=""

DEPEND="virtual/libusb:0"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${PN}v${PV}LinuxMacSource

src_prepare() {
	# Patch adds /usr/share/pk2 to the default search for the device file
	epatch "${FILESDIR}/${PN}-add-share-dir-for-dev-file-${PV}.patch"

	# Fix up the Makefile
	sed -i 's:#TARGET=linux:TARGET=linux:' Makefile
	sed -i 's:DBG=-O2:DBG=:' Makefile
	sed -i 's:^CFLAGS=:CFLAGS+=:' Makefile
	sed -i 's:^LDFLAGS=:LDFLAGS+=:' Makefile
	sed -i 's:^LIBUSB=/usr/local:LIBUSB=/usr:' Makefile
	sed -i "s:^CC=g++::" Makefile
}

src_compile() {
	emake CC="$(tc-getCXX)"
}

src_install() {
	# Copy the device files and PicKit2 OS
	insinto "/usr/share/pk2"
	doins PK2DeviceFile.dat
	doins PK2V023200.hex
	# Install the program
	exeinto /usr/bin
	doexe pk2cmd
	# Install the documentation
	dodoc ReadmeForPK2CMDLinux2-6.txt usbhotplug.txt
}