app-misc/devtodo/devtodo-0.1.18.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/devtodo/devtodo-0.1.18.ebuild,v 1.1 2004/09/11 15:31:51 ka0ttic Exp $

inherit eutils gnuconfig

DESCRIPTION="A nice command line todo list for developers"
HOMEPAGE="http://swapoff.org/DevTodo"
SRC_URI="http://swapoff.org/files/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~mips ~alpha ~hppa ~amd64 ~ia64 ~s390"
IUSE=""

RDEPEND=">=sys-libs/ncurses-5.2 >=sys-libs/readline-4.1"
DEPEND="${RDEPEND} sys-devel/automake"

src_unpack() {
	unpack ${A}
	cd ${S}

	# bug #55371
	epatch ${FILESDIR}/${PN}-1.1.17-notdl.patch

	gnuconfig_update
}

src_compile() {
	automake
	econf --sysconfdir=/etc/devtodo || die
	emake || die
}

src_install() {
	make DESTDIR=${D} install || die
	dodoc AUTHORS ChangeLog QuickStart README TODO doc/scripts.sh \
		doc/scripts.tcsh doc/todorc.example contrib/tdrec

	insinto /usr/share/bash-completion
	newins ${FILESDIR}/${PN}.bash-completion ${PN}
}

pkg_postinst() {
	echo
	einfo "Because of a conflict with app-misc/tdl, the tdl symbolic link"
	einfo "and manual page have been removed."
	einfo "If you upgraded from a previous version, you may have to manually"
	einfo "remove the symbolic links:"
	einfo "  /usr/bin/tdl -> /usr/bin/devtodo"
	einfo "  /usr/share/man/man1/tdl.1.gz -> /usr/share/man/man1/devtodo.1.gz"
	echo
	einfo "To enable command-line completion for devtodo, issue the following"
	einfo "command as root:"
	einfo "  ln -s /usr/share/bash-completion/devtodo /etc/bash_completion.d/"
	echo
}