1 files changed, 68 insertions, 0 deletions
diff --git a/net-proxy/squidguard/squidguard-1.4-r4.ebuild b/net-proxy/squidguard/squidguard-1.4-r4.ebuild
new file mode 100644
index 000000000000..c18a879f755a
--- /dev/null
+++ b/net-proxy/squidguard/squidguard-1.4-r4.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidguard/squidguard-1.4-r4.ebuild,v 1.1 2009/11/28 08:45:27 mrness Exp $
+
+WANT_AUTOMAKE=none
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="Combined filter, redirector and access controller plugin for Squid."
+HOMEPAGE="http://www.squidguard.org"
+SRC_URI="http://www.squidguard.org/Downloads/squidGuard-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="ldap"
+
+RDEPEND=">=sys-libs/db-2
+	ldap? ( net-nds/openldap )"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex"
+
+S="${WORKDIR}/squidGuard-${PV}"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-gentoo.patch"
+	epatch "${FILESDIR}/${P}-autoheader.patch"
+	epatch "${FILESDIR}/${P}-vsnprintf.patch"
+	epatch "${FILESDIR}/${P}-cross-compile.patch"
+	epatch "${FILESDIR}/${P}-upstream-fixes.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with ldap) \
+		--with-sg-config=/etc/squidGuard/squidGuard.conf \
+		--with-sg-logdir=/var/log/squidGuard \
+		|| die "configure has failed"
+}
+
+src_install() {
+	emake prefix="/usr" INSTDIR="${D}" install || die "emake install has failed"
+
+	keepdir /var/log/squidGuard
+	fowners squid:squid /var/log/squidGuard
+
+	insinto /etc/squidGuard/sample
+	doins "${FILESDIR}"/squidGuard.conf.*
+	insinto /etc/squidGuard/sample/db
+	doins "${FILESDIR}"/blockedsites
+
+	dodoc ANNOUNCE CHANGELOG README
+	dohtml doc/*.html
+	docinto text
+	dodoc doc/*.txt
+}
+
+pkg_postinst() {
+	einfo "To enable squidGuard, add the following lines to /etc/squid/squid.conf:"
+	einfo "    url_rewrite_program /usr/bin/squidGuard"
+	einfo "    url_rewrite_children 10"
+	einfo ""
+	einfo "Remember to edit /etc/squidGuard/squidGuard.conf first!"
+	einfo "Examples can be found in /etc/squidGuard/sample/"
+}