1 files changed, 73 insertions, 0 deletions
diff --git a/games-puzzle/tanglet/tanglet-1.2.2.ebuild b/games-puzzle/tanglet/tanglet-1.2.2.ebuild
new file mode 100644
index 000000000000..262f6ffeaa2c
--- /dev/null
+++ b/games-puzzle/tanglet/tanglet-1.2.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/tanglet/tanglet-1.2.2.ebuild,v 1.1 2014/05/19 19:54:12 tupone Exp $
+
+EAPI=5
+
+LANGS="cs de es en fr he hu it nl ro tr uk"
+LANGSLONG="es_CL"
+inherit eutils gnome2-utils qt4-r2 games
+
+DESCRIPTION="A single player word finding game based on Boggle"
+HOMEPAGE="http://gottcode.org/tanglet/"
+SRC_URI="http://gottcode.org/${PN}/${P}-src.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="sys-libs/zlib
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-datadir.patch
+	sed -i -e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
+		src/locale_dialog.cpp \
+		src/main.cpp \
+		|| die "sed failed"
+}
+
+src_configure() {
+	qt4-r2_src_configure
+}
+
+src_install() {
+	dogamesbin ${PN}
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r data
+	#translations
+	insinto "${GAMES_DATADIR}"/${PN}/translations/
+	for lang in ${LINGUAS};do
+		for x in ${LANGS};do
+			if [[ ${lang} == ${x} ]];then
+				doins translations/${PN}_${x}.qm
+			fi
+		done
+	done
+
+	insinto /usr/share/icons
+	doins -r icons/hicolor
+
+	dodoc ChangeLog CREDITS NEWS
+
+	doicon icons/${PN}.xpm
+	domenu icons/${PN}.desktop
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	games_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	games_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}