1 files changed, 0 insertions, 120 deletions
diff --git a/dev-python/sip/sip-4.14.2-r1.ebuild b/dev-python/sip/sip-4.14.2-r1.ebuild
deleted file mode 100644
index 077267a51834..000000000000
--- a/dev-python/sip/sip-4.14.2-r1.ebuild
+++ /dev/null
@@ -1,120 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sip/sip-4.14.2-r1.ebuild,v 1.1 2013/01/29 18:40:02 kensington Exp $
-
-EAPI=5
-PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2} )
-
-inherit eutils python-r1 toolchain-funcs
-
-DESCRIPTION="Python extension module generator for C and C++ libraries"
-HOMEPAGE="http://www.riverbankcomputing.co.uk/software/sip/intro http://pypi.python.org/pypi/SIP"
-LICENSE="|| ( GPL-2 GPL-3 sip )"
-
-if [[ ${PV} == *9999* ]]; then
-	# live version from mercurial repo
-	EHG_REPO_URI="http://www.riverbankcomputing.com/hg/sip"
-	inherit mercurial
-elif [[ ${PV} == *_pre* ]]; then
-	# development snapshot
-	HG_REVISION=
-	MY_P=${PN}-${PV%_pre*}-snapshot-${HG_REVISION}
-	SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${MY_P}.tar.gz"
-	S=${WORKDIR}/${MY_P}
-else
-	# official release
-	SRC_URI="mirror://sourceforge/pyqt/${P}.tar.gz"
-fi
-
-# Sub-slot based on SIP_API_MAJOR_NR from siplib/sip.h.in
-SLOT="0/9"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
-IUSE="debug doc"
-
-DEPEND="${PYTHON_DEPS}"
-RDEPEND="${DEPEND}"
-
-[[ ${PV} == *9999* ]] && DEPEND+="
-	=dev-lang/python-2*
-	sys-devel/bison
-	sys-devel/flex
-	doc? ( dev-python/sphinx[$(python_gen_usedep python2*)] )
-"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-4.9.3-darwin.patch
-
-	if [[ ${PV} == *9999* ]]; then
-		python2 build.py prepare || die
-		if use doc; then
-			python2 build.py doc || die
-		fi
-	fi
-
-	# Sub-slot sanity check
-	local sub_slot=${SLOT#*/}
-	local sip_api_major_nr=$(sed -nre 's:^#define SIP_API_MAJOR_NR\s+([0-9]+):\1:p' siplib/sip.h.in)
-	if [[ ${sub_slot} != ${sip_api_major_nr} ]]; then
-		eerror
-		eerror "Ebuild sub-slot (${sub_slot}) does not match SIP_API_MAJOR_NR (${sip_api_major_nr})"
-		eerror "Please update SLOT variable as follows:"
-		eerror "    SLOT=\"${SLOT%%/*}/${sip_api_major_nr}\""
-		eerror
-		die "sub-slot sanity check failed"
-	fi
-
-	python_copy_sources
-}
-
-src_configure() {
-	configuration() {
-		pushd "${BUILD_DIR}" > /dev/null
-		local myconf=(
-			"${PYTHON}" configure.py
-			--bindir="${EPREFIX}/usr/bin"
-			--destdir="${EPREFIX}$(python_get_sitedir)"
-			--incdir="${EPREFIX}$(python_get_includedir)"
-			--sipdir="${EPREFIX}/usr/share/sip"
-			$(use debug && echo --debug)
-			AR="$(tc-getAR) cqs"
-			CC="$(tc-getCC)"
-			CFLAGS="${CFLAGS}"
-			CFLAGS_RELEASE=
-			CXX="$(tc-getCXX)"
-			CXXFLAGS="${CXXFLAGS}"
-			CXXFLAGS_RELEASE=
-			LINK="$(tc-getCXX)"
-			LINK_SHLIB="$(tc-getCXX)"
-			LFLAGS="${LDFLAGS}"
-			LFLAGS_RELEASE=
-			RANLIB=
-			STRIP=
-		)
-		echo "${myconf[@]}"
-		"${myconf[@]}"
-		popd > /dev/null
-	}
-	python_foreach_impl configuration
-}
-
-src_compile() {
-	compilation() {
-		pushd "${BUILD_DIR}" > /dev/null
-		default
-		popd > /dev/null
-	}
-	python_foreach_impl compilation
-}
-
-src_install() {
-	installation() {
-		pushd "${BUILD_DIR}" > /dev/null
-		emake DESTDIR="${D}" install
-		python_optimize
-		popd > /dev/null
-	}
-	python_foreach_impl installation
-
-	dodoc NEWS
-	use doc && dohtml -r doc/html/*
-}