http://my.opera.com/desktopteam/blog/2011/06/06/post-search-and-platform-fixes

Package-Manager: portage-2.2.0_alpha37/cvs/Linux x86_64

3 files changed, 248 insertions, 5 deletions

diff --git a/www-client/opera-next/ChangeLog b/www-client/opera-next/ChangeLog
index b75a77a9fb3d..fea78a82d58e 100644
--- a/www-client/opera-next/ChangeLog
+++ b/www-client/opera-next/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/opera-next
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.14 2011/06/04 17:54:09 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.15 2011/06/06 22:04:07 jer Exp $
+
+*opera-next-11.50.1035 (06 Jun 2011)
+
+  06 Jun 2011; Jeroen Roovers <jer@gentoo.org> +opera-next-11.50.1035.ebuild:
+  http://my.opera.com/desktopteam/blog/2011/06/06/post-search-and-platform-fixe
+  s
 
   04 Jun 2011; Jeroen Roovers <jer@gentoo.org> opera-next-11.50.1031.ebuild:
   Add a simple linguas counter.
diff --git a/www-client/opera-next/Manifest b/www-client/opera-next/Manifest
index 89cc2d81c0a4..d27b4464938f 100644
--- a/www-client/opera-next/Manifest
+++ b/www-client/opera-next/Manifest
@@ -25,6 +25,9 @@ DIST opera-next-11.50-1027.x86_64.linux.tar.xz 11607112 RMD160 a077c23ea09282f38
 DIST opera-next-11.50-1031.i386.freebsd.tar.xz 10880512 RMD160 b80ee9395eacf599d82b12a660bece84581afdb5 SHA1 7010deb0c4f8322035ba753471ef17fa61dd4a5b SHA256 a5cc531ff10cdefe7f2451efb7192ca12a0f2fa5f80ff7d867af4370033aac08
 DIST opera-next-11.50-1031.i386.linux.tar.xz 10834884 RMD160 511bcfb1d83f0d95253605bc12963956fb48c06e SHA1 558dc1776d0823b854f51cb6b4d2dce56956ce19 SHA256 c8caa5019f7e0fad20ca2866080e1e5dc977ea013fc47080cb1c104bcf4a71c7
 DIST opera-next-11.50-1031.x86_64.linux.tar.xz 11603108 RMD160 7d080158bbed78df2997af7e60f7f8bb989eb179 SHA1 3a9b2d3d680bc0c74e69db1586ceff345393f09e SHA256 bbfc29e8621172bad0f51b1a524a8bc4479cd07b67dbdf198b11bef79eff0c30
+DIST opera-next-11.50-1035.i386.freebsd.tar.xz 10882692 RMD160 78c7aabb68f8c334c4f3fa5c181315d3dfde8c95 SHA1 16ca56048076a9bec175c9c5bd8c926b8dfa9777 SHA256 a6b21ddff36e5fcfcf724c1f93266cb3b0b952eb8ac7d29e958b62a9c357be8d
+DIST opera-next-11.50-1035.i386.linux.tar.xz 10835888 RMD160 debca9d12f6c6d2e793b34ec22347639c4ef071f SHA1 8ff6166cbf210398771debae3c9724ff9d5660f2 SHA256 de18a0acbd3a0308140298d0cfba8cc5a41dcad56352ec5545f8a1906e74487d
+DIST opera-next-11.50-1035.x86_64.linux.tar.xz 11602508 RMD160 cf82dfc340cc662261775affa2667bffe4877501 SHA1 d18314c40737c1c3ae1d1f33dfdfa7abf72d5cb8 SHA256 a658f1f366d7ec17c17922242eb1a9d1d02b284607c5a18006360f5fe4c2f7d5
 EBUILD opera-next-11.50.1009.ebuild 5938 RMD160 88b7c94fb996540e5a211fcf2ce278ac2dff6cc8 SHA1 e8b73ada5b8ce747ef697229b6cca2b3d67052d8 SHA256 68106e4e0a47620e1ca868822efcc9ae717cc6663fb30a9e830662fa1ebee498
 EBUILD opera-next-11.50.1015.ebuild 5946 RMD160 8da970b0a9d46985bb7ec456b3f327d2bef98f77 SHA1 1c7c770600862cd83f8b80837b857314c4f5390c SHA256 97cddad9846cf6e75202a619c0072df215f46d4d5b403c7af0ad8ff4c66d5964
 EBUILD opera-next-11.50.1016.ebuild 5947 RMD160 fa066a659b2b0d2fdbb9afb8dda8742f3717ce44 SHA1 6fee78bed4ca2a75d12fa9c3386fa8fadc083d7e SHA256 22708e79fa8c6b392b7919253a6f2a31a8a468c6a9277dd81672c668bede3035
@@ -33,12 +36,13 @@ EBUILD opera-next-11.50.1020.ebuild 5948 RMD160 22668f9b0653e83abcd68cf3acfcc23f
 EBUILD opera-next-11.50.1024.ebuild 5947 RMD160 bff8ceee7ad636ebf9e5197b655541d0d1dee3dd SHA1 c63c6cf33b385f988192925c3408bed910c9eb34 SHA256 3cc5c1737154a07c4dbc9fab3390b9cc7f5e9d52b91f8d83bff84b2c8f1ad526
 EBUILD opera-next-11.50.1027.ebuild 5938 RMD160 365cffea47d27c23f37d02590da7ebeef7d2b132 SHA1 19f9197f18a11e0a63f4da3ce9c2beb4aac0e164 SHA256 91e13980bff1c670560b828dfac95cec27e6b5d667fea0f2b68e8bb64c1ae38a
 EBUILD opera-next-11.50.1031.ebuild 6197 RMD160 bfa4cc0a6ea5804dfe28d2511d867ce8ad3ccaef SHA1 88c237a903bde66607e808bf469640c13bba6bba SHA256 e9e5fcdb8330552beab75a8b38b839f344f6a41f796353217dccdd6ebeef8386
-MISC ChangeLog 2577 RMD160 97f939d2662e14217ad09672469e4399472367b0 SHA1 1da5f1919d2ddb0cadd178f0533bb399323e80c9 SHA256 fd3aed620ebd5a24068c82620ae831885c4dd85a73eec1bd1bf1dc4ea4b8b39e
+EBUILD opera-next-11.50.1035.ebuild 6195 RMD160 d039a248078cb351911758f8facac0d909fb603d SHA1 7882b3e5ab1bbd9e325e51870c4f61b312eb3a7f SHA256 ea11842045c8f6dce62e8a507941f27d62fb83482e0e583fcfb33a4b4be27ef6
+MISC ChangeLog 2778 RMD160 961ce1bac9e90fb787ad6a2f071eef63293fab99 SHA1 201ec2676d220feaa2658b8e6825905bde3a94cd SHA256 10ec4c79aee2502d74ca39b822b9bb3fdacc16ce250dd851d2f82e3228fe852f
 MISC metadata.xml 1547 RMD160 465d146bcfdb6553f7f0ab2dddd68c4dcb2e7731 SHA1 1afb7e0ccc0833ba0eb73be38b282b66ad629ff6 SHA256 5cfc6e7cbf3c454d563eb407b4569f0f5a9b3ce7770026d6055f27211d481915
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iEYEARECAAYFAk3qcUcACgkQVWmRsqeSphNn1wCeNG5aCTpdJkZCK5EQK5dM0C0W
-hkgAnjWsk4ldWWUfYsBhVMpKD9djQ9jn
-=iizd
+iEYEARECAAYFAk3tTt0ACgkQVWmRsqeSphM/KwCfUXM+wLNuaFWpJaQZdAhGWKcO
+I+UAn3Mu+hwBR9eEXhuD6xXveHotowin
+=j//T
 -----END PGP SIGNATURE-----
diff --git a/www-client/opera-next/opera-next-11.50.1035.ebuild b/www-client/opera-next/opera-next-11.50.1035.ebuild
new file mode 100644
index 000000000000..695025d6cf10
--- /dev/null
+++ b/www-client/opera-next/opera-next-11.50.1035.ebuild
@@ -0,0 +1,233 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/opera-next-11.50.1035.ebuild,v 1.1 2011/06/06 22:04:07 jer Exp $
+
+EAPI="3"
+
+inherit eutils fdo-mime gnome2-utils multilib pax-utils versionator
+
+DESCRIPTION="A fast and secure web browser and Internet suite"
+HOMEPAGE="http://www.opera.com/"
+
+SLOT="0"
+LICENSE="OPERA-11 LGPL-2 LGPL-3"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="elibc_FreeBSD gtk kde +gstreamer"
+
+O_V="$(get_version_component_range 1-2)" # Major version, i.e. 11.00
+O_B="$(get_version_component_range 3)"   # Build version, i.e. 1156
+
+O_D="monday_${O_V}-${O_B}"
+O_P="${PN}-${O_V}-${O_B}"
+O_U="http://snapshot.opera.com/unix/"
+
+SRC_URI="
+	amd64? ( ${O_U}${O_D}/${O_P}.x86_64.linux.tar.xz )
+	x86? ( ${O_U}${O_D}/${O_P}.i386.linux.tar.xz )
+	x86-fbsd? ( ${O_U}${O_D}/${O_P}.i386.freebsd.tar.xz )
+"
+
+OPREFIX="/usr/$(get_libdir)"
+
+QA_DT_HASH="${OPREFIX}/${PN}/.*"
+QA_PRESTRIPPED="${OPREFIX}/${PN}/.*"
+
+O_LINGUAS="
+	af az be bg cs da de el en-GB es-ES es-LA et fi fr fr-CA fy gd hi hr hu id
+	it ja ka ko lt me mk ms nb nl nn pl pt pt-BR ro ru sk sr sv ta te th tl tr
+	uk uz vi zh-CN zh-TW
+"
+
+for O_LINGUA in ${O_LINGUAS}; do
+	IUSE="${IUSE} linguas_${O_LINGUA/-/_}"
+done
+
+DEPEND="
+	>=sys-apps/sed-4
+	app-arch/xz-utils
+"
+GTKRDEPEND="
+	dev-libs/atk
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/pango
+	x11-libs/pixman
+"
+KDERDEPEND="
+	kde-base/kdelibs
+	x11-libs/qt-core
+	x11-libs/qt-gui
+"
+GSTRDEPEND="
+	dev-libs/glib
+	dev-libs/libxml2
+	media-plugins/gst-plugins-meta
+	media-libs/gstreamer
+"
+RDEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXrender
+	gtk? ( ${GTKRDEPEND} )
+	kde? ( ${KDERDEPEND} )
+	gstreamer? ( ${GSTRDEPEND} )
+"
+
+pkg_setup() {
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+	elog "If you seek support, please file a bug report at"
+	elog "https://bugs.gentoo.org and post the output of"
+	elog " \`emerge --info =${CATEGORY}/${P}'"
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv -v ${PN}* "${S}" || die
+}
+
+src_prepare() {
+	local LNGDIR="share/${PN}/locale"
+
+	# Count linguas
+	count() { echo ${#}; }
+	local lingua_count=$(count ${O_LINGUAS} en)
+	local locale_count=$(count ${LNGDIR}/*)
+	[[ ${lingua_count} = ${locale_count} ]] \
+		|| die "Number of LINGUAS does not match number of locales"
+	unset count
+
+	# Remove unwanted linguas
+	einfo "Keeping these locales (linguas): ${LINGUAS}."
+	for LINGUA in ${O_LINGUAS}; do
+		if ! use linguas_${LINGUA/-/_}; then
+			LINGUA=$(find "${LNGDIR}" -maxdepth 1 -type d -iname ${LINGUA/_/-})
+			rm -r "${LINGUA}" || die "The list of linguas needs to be fixed"
+		fi
+	done
+
+	# Remove doc directory but keep the LICENSE under another name (bug #315473)
+	mv share/doc/${PN}/LICENSE share/${PN}/defaults/license.txt
+	rm -rf share/doc
+	for locale in share/${PN}/locale/*; do
+		rm -f "${locale}/license.txt"
+		ln -sn /usr/share/${PN}/defaults/license.txt "${locale}/license.txt" \
+			|| die "ln -sn license.txt"
+	done
+
+	# Remove package directory
+	rm -rf share/${PN}/package
+
+	# Leave libopera*.so only if the user chooses
+	if ! use gtk; then
+		rm lib/${PN}/liboperagtk.so || die "rm liboperagtk.so failed"
+	fi
+	if ! use kde; then
+		rm lib/${PN}/liboperakde4.so || die "rm liboperakde4.so failed"
+	fi
+
+	# Unzip the man pages before sedding
+	gunzip share/man/man1/* || die "gunzip failed"
+
+	# Replace PREFIX, SUFFIX and PN in various files
+	sed -i \
+		-e "s:@@{PREFIX}:/usr:g" \
+		-e "s:@@{SUFFIX}::g" \
+		-e "s:@@{_SUFFIX}::g" \
+		-e "s:@@{USUFFIX}::g" \
+		-e "s:opera:${PN}:g" \
+		share/man/man1/* \
+		share/applications/${PN}-browser.desktop \
+		|| die "sed failed"
+
+	# Create /usr/bin/opera wrapper
+	echo '#!/bin/sh' > ${PN}
+	echo 'export OPERA_DIR=/usr/share/'"${PN}" >> ${PN}
+	echo 'export OPERA_PERSONALDIR=${OPERA_PERSONALDIR:-"${HOME}/.'${PN}'"}' \
+		>> ${PN}
+	echo 'exec '"${OPREFIX}/${PN}/${PN}"' "$@"' >> ${PN}
+
+	# Fix libdir in defaults/pluginpath.ini
+	sed -i \
+		share/${PN}/defaults/pluginpath.ini \
+		-e "s|/usr/lib32|${OPREFIX}|g" \
+		-e '/netscape/{s|[0-1]|2|g}' \
+		|| die "sed pluginpath.ini failed"
+
+	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
+	if use elibc_FreeBSD; then
+		scanelf -qR -N libz.so.3 -F "#N" lib/${PN}/ | \
+		while read i; do
+			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
+			then
+				export SANITY_CHECK_LIBZ_FAILED=1
+				break
+			fi
+			sed -i \
+				"$i" \
+				-e 's/libz\.so\.3/libz.so.1/g'
+		done
+		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] \
+			&& die "failed to change libz.so.3 to libz.so.1"
+	fi
+}
+
+src_install() {
+	# We install into usr instead of opt as Opera does not support the latter
+	dodir /usr
+	mv lib/ "${D}/${OPREFIX}" || die "mv lib/ failed"
+	mv share/ "${D}/usr/" || die "mv share/ failed"
+
+	# Install startup scripts
+	dobin ${PN} || die "dobin failed"
+
+	# Stop revdep-rebuild from checking opera binaries
+	dodir /etc/revdep-rebuild
+	echo "SEARCH_DIRS_MASK=\"${OPREFIX}/${PN}\"" \
+		> "${D}"/etc/revdep-rebuild/90${PN}
+
+	# Set PaX markings for hardened/PaX (bug #344267)
+	pax-mark m \
+		"${D}/${OPREFIX}/${PN}/${PN}" \
+		"${D}/${OPREFIX}/${PN}/operaplugincleaner" \
+		"${D}/${OPREFIX}/${PN}/operapluginwrapper"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	elog "To change the UI language, choose [Tools] -> [Preferences], open the"
+	elog "[General] tab, click on [Details...] then [Choose...] and point the"
+	elog "file chooser at /usr/share/${PN}/locale/, then enter the"
+	elog "directory for the language you want and [Open] the .lng file."
+
+	if use elibc_FreeBSD; then
+		elog
+		elog "To improve shared memory usage please set:"
+		elog "$ sysctl kern.ipc.shm_allow_removed=1"
+	fi
+
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}