http://my.opera.com/desktopteam/blog/2011/07/07/introducing-opera-wahoo

Package-Manager: portage-2.2.0_alpha43/cvs/Linux i686

3 files changed, 245 insertions, 5 deletions

diff --git a/www-client/opera-next/ChangeLog b/www-client/opera-next/ChangeLog
index 4c25090a6372..ecb2204cb87f 100644
--- a/www-client/opera-next/ChangeLog
+++ b/www-client/opera-next/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/opera-next
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.29 2011/06/28 06:51:39 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.30 2011/07/07 15:09:21 jer Exp $
+
+*opera-next-12.00.1017 (07 Jul 2011)
+
+  07 Jul 2011; Jeroen Roovers <jer@gentoo.org> +opera-next-12.00.1017.ebuild:
+  http://my.opera.com/desktopteam/blog/2011/07/07/introducing-opera-wahoo
 
   28 Jun 2011; Jeroen Roovers <jer@gentoo.org> -opera-next-11.50.1027.ebuild,
   -opera-next-11.50.1031.ebuild, -opera-next-11.50.1035.ebuild,
diff --git a/www-client/opera-next/Manifest b/www-client/opera-next/Manifest
index febf95ba722a..07ef8eeb077f 100644
--- a/www-client/opera-next/Manifest
+++ b/www-client/opera-next/Manifest
@@ -4,13 +4,17 @@ Hash: SHA1
 DIST opera-next-11.50-1074.i386.freebsd.tar.xz 11163176 RMD160 986dea489a1494c08c821fa8023d125200459cef SHA1 9547c3f9e273f9fa149975639d05f5e7089bf939 SHA256 e0ab37552f0233c789b95d94f65164f1e3b8af0500246fcdfe8ea97a6cf2dec7
 DIST opera-next-11.50-1074.i386.linux.tar.xz 11092584 RMD160 ade9e1094e0eaeab41a78e087c72e67d3b70f015 SHA1 633b86baffc8d9002f8b8c2afd36658bdb0f778d SHA256 dde4e447faa91a603e6713925e2bb99e452ae7306a44fe423860cbfc468549a3
 DIST opera-next-11.50-1074.x86_64.linux.tar.xz 11845592 RMD160 2c901da76fb3ccc9c618b79b0dc1fb7056531b8d SHA1 43eda198b21287bd8487862fb0abb064f188b63b SHA256 d4dee15432927b903bc931ab009c525bfcde23b22d1eeb20b745b5618c3a995a
+DIST opera-next-12.00-1017.i386.freebsd.tar.xz 11185548 RMD160 6a98a57dcb72f0750ffcc5c5102aeb9b50643acd SHA1 bee15947de2c3a8b3352fa43dfd17fbca09e9aec SHA256 a942906cc8edc0b528ab33269d72dbf26dc48bfe17a7870753b24915a43e3ff8
+DIST opera-next-12.00-1017.i386.linux.tar.xz 11113544 RMD160 c43afafc28591ad53d622f30a54eeeefc47db689 SHA1 2255f6dae7ab2c1ace0bc3106e319f7477229ff4 SHA256 6226602342f5146a6e1f48894c2b6d1ed9265f05a6f8f14444b89cc139f98968
+DIST opera-next-12.00-1017.x86_64.linux.tar.xz 11860500 RMD160 3bfe63ed2fcea71023b3e5ce832af433f063b6b5 SHA1 8e37dce43b960abfba9a80a26b851b0d248609f8 SHA256 328a5c699dd218ffed420b12787a2d4103fa92389438320e49163b50641a57e8
 EBUILD opera-next-11.50.1074.ebuild 6199 RMD160 790193982d0445f3087cea0b03dfe01e3febdbb8 SHA1 f70964c6766a606c1d3289354cfc89adef27d2c9 SHA256 c3400782dba0fd46968d2ef7c0d43a2692156212cb7b7c8e10ba4733c9944438
-MISC ChangeLog 5818 RMD160 22a8d22525c8de29548a849be1e637b5e0433f39 SHA1 eee18309f52c0bdff158a4f03c2688c13e8af072 SHA256 5d137d3642b12d5440056ce4d8da63987f49ba30e91dca09fe6477c7946cb5c7
+EBUILD opera-next-12.00.1017.ebuild 6201 RMD160 d789458dbd1a8d4e35f03dfb4b8f40d3888c0415 SHA1 9da734fd4d669f0023e753e3f0345b0157320ec2 SHA256 4a3bcdf39cfdf1282ed2bc8317d9641d03a291b913860b73c673e35a1b14b549
+MISC ChangeLog 6009 RMD160 a60cdf47b7675f093e993e3bdc331d80348fd76a SHA1 f4a9523612cb99f5941404699cd54a35486b6095 SHA256 ce6e0461c260b73ed34614f51636975b6f796d0a6d10f8837eaef2b6959dde6a
 MISC metadata.xml 1547 RMD160 465d146bcfdb6553f7f0ab2dddd68c4dcb2e7731 SHA1 1afb7e0ccc0833ba0eb73be38b282b66ad629ff6 SHA256 5cfc6e7cbf3c454d563eb407b4569f0f5a9b3ce7770026d6055f27211d481915
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iEYEARECAAYFAk4JegAACgkQVWmRsqeSphMDdACdFJVB7GLqWg57PYzlqC5WWDW+
-w+8AnAuUwHvALwZXr1auyUf43qAzPcFh
-=Fdjb
+iEYEARECAAYFAk4VzCYACgkQVWmRsqeSphNzpgCeM1/01WEeU5yZ8W0Tuis494VO
+lqUAn2KVTGnDI7SrzEPE+B2WCfdOT9qf
+=ZKKm
 -----END PGP SIGNATURE-----
diff --git a/www-client/opera-next/opera-next-12.00.1017.ebuild b/www-client/opera-next/opera-next-12.00.1017.ebuild
new file mode 100644
index 000000000000..a9c3941b613a
--- /dev/null
+++ b/www-client/opera-next/opera-next-12.00.1017.ebuild
@@ -0,0 +1,231 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/opera-next-12.00.1017.ebuild,v 1.1 2011/07/07 15:09:21 jer Exp $
+
+EAPI="3"
+
+inherit eutils fdo-mime gnome2-utils multilib pax-utils versionator
+
+DESCRIPTION="A fast and secure web browser and Internet suite"
+HOMEPAGE="http://www.opera.com/"
+
+SLOT="0"
+LICENSE="OPERA-11 LGPL-2 LGPL-3"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="elibc_FreeBSD gtk kde +gstreamer"
+
+O_V="$(get_version_component_range 1-2)" # Major version, i.e. 11.00
+O_B="$(get_version_component_range 3)"   # Build version, i.e. 1156
+
+O_D="wahoo_${O_V}-${O_B}"
+O_P="${PN}-${O_V}-${O_B}"
+O_U="http://snapshot.opera.com/unix/"
+
+SRC_URI="
+	amd64? ( ${O_U}${O_D}/${O_P}.x86_64.linux.tar.xz )
+	x86? ( ${O_U}${O_D}/${O_P}.i386.linux.tar.xz )
+	x86-fbsd? ( ${O_U}${O_D}/${O_P}.i386.freebsd.tar.xz )
+"
+
+OPREFIX="/usr/$(get_libdir)"
+
+QA_DT_HASH="${OPREFIX}/${PN}/.*"
+QA_PRESTRIPPED="${OPREFIX}/${PN}/.*"
+
+O_LINGUAS="af az be bg bn cs da de el en-GB es-ES es-LA et fi fr fr-CA fy gd hi
+hr hu id it ja ka ko lt me mk ms nb nl nn pa pl pt pt-BR ro ru sk sr sv sw ta te
+th tl tr uk uz vi zh-CN zh-TW zu"
+
+for O_LINGUA in ${O_LINGUAS}; do
+	IUSE="${IUSE} linguas_${O_LINGUA/-/_}"
+done
+
+DEPEND="
+	>=sys-apps/sed-4
+	app-arch/xz-utils
+"
+GTKRDEPEND="
+	dev-libs/atk
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/pango
+	x11-libs/pixman
+"
+KDERDEPEND="
+	kde-base/kdelibs
+	x11-libs/qt-core
+	x11-libs/qt-gui
+"
+GSTRDEPEND="
+	dev-libs/glib
+	dev-libs/libxml2
+	media-plugins/gst-plugins-meta
+	media-libs/gstreamer
+"
+RDEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXrender
+	gtk? ( ${GTKRDEPEND} )
+	kde? ( ${KDERDEPEND} )
+	gstreamer? ( ${GSTRDEPEND} )
+"
+
+pkg_setup() {
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+	elog "If you seek support, please file a bug report at"
+	elog "https://bugs.gentoo.org and post the output of"
+	elog " \`emerge --info =${CATEGORY}/${P}'"
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv -v ${PN}* "${S}" || die
+}
+
+src_prepare() {
+	local LNGDIR="share/${PN}/locale"
+
+	# Count linguas
+	count() { echo ${#}; }
+	local lingua_count=$(count ${O_LINGUAS} en)
+	local locale_count=$(count ${LNGDIR}/*)
+	[[ ${lingua_count} = ${locale_count} ]] \
+		|| die "Number of LINGUAS does not match number of locales"
+	unset count
+
+	# Remove unwanted linguas
+	einfo "Keeping these locales (linguas): ${LINGUAS}."
+	for LINGUA in ${O_LINGUAS}; do
+		if ! use linguas_${LINGUA/-/_}; then
+			LINGUA=$(find "${LNGDIR}" -maxdepth 1 -type d -iname ${LINGUA/_/-})
+			rm -r "${LINGUA}" || die "The list of linguas needs to be fixed"
+		fi
+	done
+
+	# Remove doc directory but keep the LICENSE under another name (bug #315473)
+	mv share/doc/${PN}/LICENSE share/${PN}/defaults/license.txt
+	rm -rf share/doc
+	for locale in share/${PN}/locale/*; do
+		rm -f "${locale}/license.txt"
+		ln -sn /usr/share/${PN}/defaults/license.txt "${locale}/license.txt" \
+			|| die "ln -sn license.txt"
+	done
+
+	# Remove package directory
+	rm -rf share/${PN}/package
+
+	# Leave libopera*.so only if the user chooses
+	if ! use gtk; then
+		rm lib/${PN}/liboperagtk.so || die "rm liboperagtk.so failed"
+	fi
+	if ! use kde; then
+		rm lib/${PN}/liboperakde4.so || die "rm liboperakde4.so failed"
+	fi
+
+	# Unzip the man pages before sedding
+	gunzip share/man/man1/* || die "gunzip failed"
+
+	# Replace PREFIX, SUFFIX and PN in various files
+	sed -i \
+		-e "s:@@{PREFIX}:/usr:g" \
+		-e "s:@@{SUFFIX}::g" \
+		-e "s:@@{_SUFFIX}::g" \
+		-e "s:@@{USUFFIX}::g" \
+		-e "s:opera:${PN}:g" \
+		share/man/man1/* \
+		share/applications/${PN}-browser.desktop \
+		|| die "sed failed"
+
+	# Create /usr/bin/opera wrapper
+	echo '#!/bin/sh' > ${PN}
+	echo 'export OPERA_DIR=/usr/share/'"${PN}" >> ${PN}
+	echo 'export OPERA_PERSONALDIR=${OPERA_PERSONALDIR:-"${HOME}/.'${PN}'"}' \
+		>> ${PN}
+	echo 'exec '"${OPREFIX}/${PN}/${PN}"' "$@"' >> ${PN}
+
+	# Fix libdir in defaults/pluginpath.ini
+	sed -i \
+		share/${PN}/defaults/pluginpath.ini \
+		-e "s|/usr/lib32|${OPREFIX}|g" \
+		-e '/netscape/{s|[0-1]|2|g}' \
+		|| die "sed pluginpath.ini failed"
+
+	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
+	if use elibc_FreeBSD; then
+		scanelf -qR -N libz.so.3 -F "#N" lib/${PN}/ | \
+		while read i; do
+			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
+			then
+				export SANITY_CHECK_LIBZ_FAILED=1
+				break
+			fi
+			sed -i \
+				"$i" \
+				-e 's/libz\.so\.3/libz.so.1/g'
+		done
+		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] \
+			&& die "failed to change libz.so.3 to libz.so.1"
+	fi
+}
+
+src_install() {
+	# We install into usr instead of opt as Opera does not support the latter
+	dodir /usr
+	mv lib/ "${D}/${OPREFIX}" || die "mv lib/ failed"
+	mv share/ "${D}/usr/" || die "mv share/ failed"
+
+	# Install startup scripts
+	dobin ${PN} || die "dobin failed"
+
+	# Stop revdep-rebuild from checking opera binaries
+	dodir /etc/revdep-rebuild
+	echo "SEARCH_DIRS_MASK=\"${OPREFIX}/${PN}\"" \
+		> "${D}"/etc/revdep-rebuild/90${PN}
+
+	# Set PaX markings for hardened/PaX (bug #344267)
+	pax-mark m \
+		"${D}/${OPREFIX}/${PN}/${PN}" \
+		"${D}/${OPREFIX}/${PN}/operaplugincleaner" \
+		"${D}/${OPREFIX}/${PN}/operapluginwrapper"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	elog "To change the UI language, choose [Tools] -> [Preferences], open the"
+	elog "[General] tab, click on [Details...] then [Choose...] and point the"
+	elog "file chooser at /usr/share/${PN}/locale/, then enter the"
+	elog "directory for the language you want and [Open] the .lng file."
+
+	if use elibc_FreeBSD; then
+		elog
+		elog "To improve shared memory usage please set:"
+		elog "$ sysctl kern.ipc.shm_allow_removed=1"
+	fi
+
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}