fix parallel make issue (#337092)

Package-Manager: portage-2.2.0_alpha14/cvs/Linux i686

1 files changed, 51 insertions, 0 deletions

diff --git a/net-misc/ipsvd/ipsvd-1.0.0-r1.ebuild b/net-misc/ipsvd/ipsvd-1.0.0-r1.ebuild
new file mode 100644
index 000000000000..87f7cccf805a
--- /dev/null
+++ b/net-misc/ipsvd/ipsvd-1.0.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/ipsvd/ipsvd-1.0.0-r1.ebuild,v 1.1 2011/01/21 00:03:04 bangert Exp $
+
+EAPI=3
+
+inherit toolchain-funcs flag-o-matic eutils
+
+DESCRIPTION="ipsvd is a set of internet protocol service daemons for Unix."
+HOMEPAGE="http://smarden.org/ipsvd/"
+SRC_URI="http://smarden.org/ipsvd/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static"
+
+DEPEND=""
+RDEPEND=""
+PROVIDE="virtual/inetd"
+
+S="${WORKDIR}/net/${P}"
+
+src_prepare() {
+	cd "${S}"/src
+	epatch "${FILESDIR}"/${P}-fix-parallel-make.diff
+}
+
+src_configure() {
+	cd "${S}"/src
+	if use static ; then
+		append-ldflags -static
+	fi
+
+	echo "$(tc-getCC) ${CFLAGS}"  > conf-cc
+	echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
+}
+
+src_compile() {
+	cd "${S}"/src
+	emake || die "make failed"
+}
+
+src_install() {
+	dobin src/{tcpsvd,udpsvd,ipsvd-cdb} || die "dobin"
+	dodoc package/{CHANGES,README}
+
+	dohtml doc/*.html
+	doman man/ipsvd-instruct.5 man/ipsvd.7 man/udpsvd.8 \
+		man/tcpsvd.8 man/ipsvd-cdb.8
+}