don't use dlopen to open libraries but instead link against them.

Package-Manager: portage-2.1.7.17/cvs/Linux i686

4 files changed, 167 insertions, 12 deletions

diff --git a/media-libs/libsdl/ChangeLog b/media-libs/libsdl/ChangeLog
index 7600374f16a9..9ee70c18d14e 100644
--- a/media-libs/libsdl/ChangeLog
+++ b/media-libs/libsdl/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libsdl
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.166 2009/11/14 07:55:24 mr_bones_ Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.167 2010/03/15 18:27:56 mr_bones_ Exp $
+
+*libsdl-1.2.14-r1 (15 Mar 2010)
+
+  15 Mar 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  +libsdl-1.2.14-r1.ebuild:
+  don't use dlopen to open libraries but instead link against them.
 
   14 Nov 2009; Michael Sterrett <mr_bones_@gentoo.org>
   libsdl-1.2.13-r1.ebuild, libsdl-1.2.14.ebuild, metadata.xml:
diff --git a/media-libs/libsdl/libsdl-1.2.14-r1.ebuild b/media-libs/libsdl/libsdl-1.2.14-r1.ebuild
new file mode 100644
index 000000000000..61077b6c9086
--- /dev/null
+++ b/media-libs/libsdl/libsdl-1.2.14-r1.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/libsdl-1.2.14-r1.ebuild,v 1.1 2010/03/15 18:27:56 mr_bones_ Exp $
+
+EAPI=2
+inherit flag-o-matic toolchain-funcs eutils libtool
+
+DESCRIPTION="Simple Direct Media Layer"
+HOMEPAGE="http://www.libsdl.org/"
+SRC_URI="http://www.libsdl.org/release/SDL-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+# WARNING:
+# if you disable the audio, video, joystick use flags or turn on the custom-cflags use flag
+# in USE and something breaks, you pick up the pieces.  Be prepared for
+# bug reports to be marked INVALID.
+IUSE="oss alsa nas X dga xv xinerama fbcon directfb ggi svga tslib aalib opengl libcaca +audio +video +joystick custom-cflags pulseaudio ps3"
+
+RDEPEND="audio? ( >=media-libs/audiofile-0.1.9 )
+	alsa? ( media-libs/alsa-lib )
+	nas? (
+		media-libs/nas
+		x11-libs/libXt
+		x11-libs/libXext
+		x11-libs/libX11
+	)
+	X? (
+		x11-libs/libXt
+		x11-libs/libXext
+		x11-libs/libX11
+		x11-libs/libXrandr
+	)
+	directfb? ( >=dev-libs/DirectFB-0.9.19 )
+	ggi? ( >=media-libs/libggi-2.0_beta3 )
+	svga? ( >=media-libs/svgalib-1.4.2 )
+	aalib? ( media-libs/aalib )
+	libcaca? ( >=media-libs/libcaca-0.9-r1 )
+	opengl? ( virtual/opengl virtual/glu )
+	ppc64? ( ps3? ( sys-libs/libspe2 ) )
+	tslib? ( x11-libs/tslib )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}
+	nas? (
+		x11-proto/xextproto
+		x11-proto/xproto
+	)
+	X? (
+		x11-proto/xextproto
+		x11-proto/xproto
+	)
+	x86? ( || ( >=dev-lang/yasm-0.6.0 >=dev-lang/nasm-0.98.39-r3 ) )"
+
+S=${WORKDIR}/SDL-${PV}
+
+pkg_setup() {
+	if use !audio || use !video || use !joystick ; then
+		ewarn "Since you've chosen to turn off some of libsdl's functionality,"
+		ewarn "don't bother filing libsdl-related bugs until trying to remerge"
+		ewarn "libsdl with the audio, video, and joystick flags in USE."
+		ewarn "You need to know what you're doing to selectively turn off parts of libsdl."
+		epause 30
+	fi
+	if use custom-cflags ; then
+		ewarn "Since you've chosen to use possibly unsafe CFLAGS,"
+		ewarn "don't bother filing libsdl-related bugs until trying to remerge"
+		ewarn "libsdl without the custom-cflags use flag in USE."
+		epause 10
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.2.13-sdl-config.patch
+
+	elibtoolize
+}
+
+src_configure() {
+	local myconf=
+	if [[ $(tc-arch) != "x86" ]] ; then
+		myconf="${myconf} --disable-nasm"
+	else
+		myconf="${myconf} --enable-nasm"
+	fi
+	use custom-cflags || strip-flags
+	use audio || myconf="${myconf} --disable-audio"
+	use video \
+		&& myconf="${myconf} --enable-video-dummy" \
+		|| myconf="${myconf} --disable-video"
+	use joystick || myconf="${myconf} --disable-joystick"
+
+	local directfbconf="--disable-video-directfb"
+	if use directfb ; then
+		# since DirectFB can link against SDL and trigger a
+		# dependency loop, only link against DirectFB if it
+		# isn't broken #61592
+		echo 'int main(){}' > directfb-test.c
+		$(tc-getCC) directfb-test.c -ldirectfb 2>/dev/null \
+			&& directfbconf="--enable-video-directfb" \
+			|| ewarn "Disabling DirectFB since libdirectfb.so is broken"
+	fi
+
+	myconf="${myconf} ${directfbconf}"
+
+	econf \
+		--disable-rpath \
+		--disable-arts \
+		--disable-esd \
+		--enable-events \
+		--enable-cdrom \
+		--enable-threads \
+		--enable-timers \
+		--enable-file \
+		--enable-cpuinfo \
+		--disable-alsa-shared \
+		--disable-esd-shared \
+		--disable-pulseaudio-shared \
+		--disable-arts-shared \
+		--disable-nas-shared \
+		--disable-x11-shared \
+		--disable-osmesa-shared \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable pulseaudio) \
+		$(use_enable nas) \
+		$(use_enable X video-x11) \
+		$(use_enable dga) \
+		$(use_enable xv video-x11-xv) \
+		$(use_enable xinerama video-x11-xinerama) \
+		$(use_enable X video-x11-xrandr) \
+		$(use_enable dga video-dga) \
+		$(use_enable fbcon video-fbcon) \
+		$(use_enable ggi video-ggi) \
+		$(use_enable svga video-svga) \
+		$(use_enable aalib video-aalib) \
+		$(use_enable libcaca video-caca) \
+		$(use_enable opengl video-opengl) \
+		$(use_enable ps3 video-ps3) \
+		$(use_enable tslib input-tslib) \
+		$(use_with X x) \
+		--disable-video-x11-xme \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc BUGS CREDITS README README-SDL.txt README.CVS TODO WhatsNew
+	dohtml -r ./
+}
diff --git a/media-libs/sdl-image/ChangeLog b/media-libs/sdl-image/ChangeLog
index 4651dec0b207..34c1e0e4b98e 100644
--- a/media-libs/sdl-image/ChangeLog
+++ b/media-libs/sdl-image/ChangeLog
@@ -1,6 +1,10 @@
 # ChangeLog for media-libs/sdl-image
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/sdl-image/ChangeLog,v 1.66 2010/02/18 18:07:19 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/sdl-image/ChangeLog,v 1.67 2010/03/15 18:24:53 mr_bones_ Exp $
+
+  15 Mar 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  sdl-image-1.2.10-r1.ebuild:
+  don't use dlopen to open libraries but instead link against them.
 
 *sdl-image-1.2.10-r1 (18 Feb 2010)
 
diff --git a/media-libs/sdl-image/sdl-image-1.2.10-r1.ebuild b/media-libs/sdl-image/sdl-image-1.2.10-r1.ebuild
index 5b510d2e4ee3..241c9dbc2845 100644
--- a/media-libs/sdl-image/sdl-image-1.2.10-r1.ebuild
+++ b/media-libs/sdl-image/sdl-image-1.2.10-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/sdl-image/sdl-image-1.2.10-r1.ebuild,v 1.1 2010/02/18 18:07:19 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/sdl-image/sdl-image-1.2.10-r1.ebuild,v 1.2 2010/03/15 18:24:53 mr_bones_ Exp $
 
 EAPI=2
 inherit autotools
@@ -24,16 +24,11 @@ RDEPEND="${DEPEND}"
 
 S=${WORKDIR}/${MY_P}
 
-src_prepare() {
-	sed -i \
-		-e 's/sort/sort -r/' \
-		configure.in \
-		|| die
-	eautoreconf
-}
-
 src_configure() {
 	econf \
+		--disable-jpg-shared \
+		--disable-png-shared \
+		--disable-tif-shared \
 		$(use_enable gif) \
 		$(use_enable jpeg jpg) \
 		$(use_enable tiff tif) \